diff --git a/dev-libs/userspace-rcu/Manifest b/dev-libs/userspace-rcu/Manifest
index 067a6f3fe511..aff40d77f297 100644
--- a/dev-libs/userspace-rcu/Manifest
+++ b/dev-libs/userspace-rcu/Manifest
@@ -1 +1,2 @@
 DIST userspace-rcu-0.15.3.tar.bz2 684175 BLAKE2B e636b04fe3bac7bb8f4afff0a7b2153e38d396a9c08e8ca19e705fcda81adda5256817db87305382c7adc3630ef5b1d25ff81af818a6b8c70232df11c9bee862 SHA512 9461f5f1ebfcfdb28bc9548738a030d0a29e754ae5340581d057c405c0fa5c17560a251fa15a20cf14d35f1fcc9aceac80841b37a5f348698da52a71ee4d4fe5
+DIST userspace-rcu-0.15.5.tar.bz2 685498 BLAKE2B 3e0ad236f77f1146ac3e7fe93ae8f3ea86632af38b78c6648a19c9df33959ff08e42779f6d34b47dfd3f7188efc39f8f4daaba81d702743e357d3bd9327000fc SHA512 48c7e137b986c1a33d91ecd8e5101ed8783b7c4e15b8324660c72bce9879373b80ffd97aca0c3b8015a47dfe2c11b5f4acf9d4a065185d9ba405d4e50a2b58d8
diff --git a/dev-libs/userspace-rcu/userspace-rcu-0.15.5.ebuild b/dev-libs/userspace-rcu/userspace-rcu-0.15.5.ebuild
new file mode 100644
index 000000000000..4dce0bee8d8d
--- /dev/null
+++ b/dev-libs/userspace-rcu/userspace-rcu-0.15.5.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Userspace RCU (read-copy-update) library"
+HOMEPAGE="https://liburcu.org/"
+SRC_URI="https://lttng.org/files/urcu/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0/8" # subslot = soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( sys-process/time )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.13.1-tests-no-benchmark.patch
+)
+
+src_prepare() {
+	default
+
+	# Needed for tests patch
+	# ... and refresh libtool (see https://github.com/gentoo/gentoo/pull/23973)
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	default
+
+	emake -C tests/regression regtest
+
+	# We don't run the benchmark tests.
+	rm tests/benchmark/test-suite.log || die
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name "*.la" -delete || die
+}