gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-06 02:17:34 -08:00
Code Issues Projects Releases Wiki Activity

dev-python/anyio: Remove old

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-05-31 12:13:26 +02:00
parent 07f102a1e3
commit bc286798ac
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
1 changed files with 0 additions and 73 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

73
dev-python/anyio/anyio-4.8.0-r2.ebuild
View File

@ -1,73 +0,0 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
inherit distutils-r1 pypi
DESCRIPTION="Compatibility layer for multiple asynchronous event loop implementations"
HOMEPAGE="
https://github.com/agronholm/anyio/
https://pypi.org/project/anyio/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
RDEPEND="
>=dev-python/idna-2.8[${PYTHON_USEDEP}]
>=dev-python/sniffio-1.1[${PYTHON_USEDEP}]
>=dev-python/truststore-0.9.1[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/typing-extensions-4.5[${PYTHON_USEDEP}]
' 3.{11..12})
"
# On amd64, let's get more test coverage by dragging in uvloop, but let's
# not bother on other arches where uvloop may not be supported.
BDEPEND="
>=dev-python/setuptools-scm-6.4[${PYTHON_USEDEP}]
test? (
>=dev-python/exceptiongroup-1.2.0[${PYTHON_USEDEP}]
>=dev-python/hypothesis-4.0[${PYTHON_USEDEP}]
>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
dev-python/trustme[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/trio-0.26.1[${PYTHON_USEDEP}]
' 3.{11..13})
amd64? (
$(python_gen_cond_dep '
>=dev-python/uvloop-0.21.0_beta1[${PYTHON_USEDEP}]
' python3_{11..13})
)
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs \
'>=dev-python/sphinx-rtd-theme-1.2.2' \
dev-python/sphinxcontrib-jquery \
dev-python/sphinx-autodoc-typehints
python_test() {
local EPYTEST_DESELECT=(
# requires link-local IPv6 interface
tests/test_sockets.py::TestTCPListener::test_bind_link_local
)
local filter=()
if ! has_version ">=dev-python/trio-0.26.1[${PYTHON_USEDEP}]"; then
filter+=( -k "not trio" )
EPYTEST_DESELECT+=(
tests/test_pytest_plugin.py::test_plugin
tests/test_pytest_plugin.py::test_autouse_async_fixture
tests/test_pytest_plugin.py::test_cancel_scope_in_asyncgen_fixture
)
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -m 'not network' "${filter[@]}"
}