dev-python/oslo-serialization: 2.24.0 bup

Package-Manager: Portage-2.3.19, Repoman-2.3.6

dev-python/oslo-serialization/Manifest

@@ -1 +1,2 @@
 DIST oslo-serialization-2.20.2.tar.gz 29486 BLAKE2B 73fda86ced11c7c6dfb1a15c761645583cee463521285dc194cc1aebd5ef100832190bb0b07f825472286dab8ffc4dbed5cf6183fd86128bd74d51c5d15996a8 SHA512 1bcf50a090a0ec74d1aca7de6cc83f7451778eae7335427d11f732120ec99163441ee0bde13df6e660574c7ac5fcafe746cdbcb421e57f02d782f2405d5e33c7
+DIST oslo-serialization-2.24.0.tar.gz 28948 BLAKE2B 8e57d14b21deefd8058f4dd677493072b0bfdc08bfb18faae2f6a09c4ab4e29ce544e479427a6c6557e0ca78fd7b525aa6a8ab3443a01c3d856ee3556f5f3f5e SHA512 8c2103409d9ec2ebfd45eefb56ed42b1ca52c0f8eaf5deff1020a67f813c8524d1bffd81d97a1ad28c80b4a5afeaebca829c4580e635f514900fd0835782990c

dev-python/oslo-serialization/oslo-serialization-2.24.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 vcs-snapshot
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Oslo Serialization library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		virtual/python-ipaddress[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+		>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/bandit-1.1.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		>=dev-python/openstackdocstheme-1.17.0[${PYTHON_USEDEP}]
+		>=dev-python/reno-2.5.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	use doc && esetup.py build_sphinx
+	distutils-r1_python_prepare_all
+}
+
+# Note: Tests fail due to requiring installation.
+#
+# Installation appears to fail due ot the use of namespace packages but root
+# cause was never truly established.
+RESTRICT="test"
+
+python_test() {
+	distutils_install_for_testing
+
+	PYTHONPATH="${TEST_DIR}/lib:${PYTHONPATH}"
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}