From b93200d3a9573f9f5bcf6e2d90d0f03d1a62b272 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 21 Feb 2026 07:18:48 +0100
Subject: [PATCH] dev-python/oslo-utils: Bump to 10.0.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-utils/Manifest                |  1 +
 .../oslo-utils/oslo-utils-10.0.0.ebuild       | 65 +++++++++++++++++++
 2 files changed, 66 insertions(+)
 create mode 100644 dev-python/oslo-utils/oslo-utils-10.0.0.ebuild

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 4806a62a9d380..65bccbc5737df 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
+DIST oslo_utils-10.0.0.tar.gz 141716 BLAKE2B cf7322afb98936f9c8261e244ff629340e6c23e2cb34d1cbff9475a7eae18796da922e8dec051f24335eaf8a19276e5c5b9e0305d7371858a4e6bf4febf3a99f SHA512 1e511b872a916256a006bc915d3f01663f6b702024423141955033490d8e48a814cfda7eca8834f0d5546624d06b02cca766ba55b5cb3808d76471234a08e608
 DIST oslo_utils-9.2.0.tar.gz 142524 BLAKE2B 6eab7fadbbb69c99e1c64b9442d28c6ced17f867d31bee72dda11fbdb180a19c1e648427b8d7560b600bcb834c1850cb3963548903ff19e3fcf8a11b3aa6a954 SHA512 ed6def990d94026637bc3143c881537b5a04d38e1e13f798a2e32d106a3056f110f147fd547a18d64bdd22f44a8de5f31a38e2f5d75dfb1fbe18ec33f5258533
diff --git a/dev-python/oslo-utils/oslo-utils-10.0.0.ebuild b/dev-python/oslo-utils/oslo-utils-10.0.0.ebuild
new file mode 100644
index 0000000000000..dd444014d93a1
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-10.0.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit check-reqs distutils-r1 pypi
+
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.utils/
+	https://github.com/openstack/oslo.utils/
+	https://pypi.org/project/oslo.utils/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+	>=dev-python/pbr-6.1.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+"
+# qemu needed for qemu-img
+BDEPEND="
+	test? (
+		app-cdr/cdrtools
+		app-emulation/qemu
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+# note this only applies to USE=test
+CHECKREQS_DISK_BUILD=8G
+
+pkg_pretend() {
+	use test && check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	use test && check-reqs_pkg_setup
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# require eventlet
+	rm oslo_utils/tests/test_eventletutils.py || die
+}