diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 8b9ccd0eeeeb7..0b6940c9f06d5 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1,3 +1,4 @@
 DIST tempest-46.0.0.tar.gz 1172210 BLAKE2B 76ebb5a5914de0cd78b737411ee38df6f349d31f3f253f184bd3ad7bf03db5c5c1139e97758edcf22702249d6a2799b66be09bd69256048397fa18d76b277efd SHA512 d6e6247f3bb4a9b5fc465c0c5d6c64aa7335a417a6614a9ae61e55d6b6a02423ebcab34867427b7b92c749d465374bb82b9915dff4e3748201b0c5e4844f402e
 DIST tempest-46.1.0.tar.gz 1180586 BLAKE2B 1639df90a10382fd4e8cec0684280fabeacb31e35835b3ed8bee553af3b8c2d757e1614fc2482f05215fff9b2a3ed5dc797a59389859cbf79f5b6b49d2023034 SHA512 d0babe574407d6d35c84926ef5adf09ad46b159aafbb4b1ec38a1debf8a4352d3e21bbd6bf5b0917541a646bd1f6061f5d4da748d602a903cf623f2afe6f0634
 DIST tempest-46.1.1.tar.gz 1180447 BLAKE2B cb74fb5ca4b283a5e6e640cd2ef938f8edc0c1946341daa40375af4755dfee320079957eee34648c5b38f001f5e87df5ed0887b2d89f79719da6e8151ae40dcf SHA512 e850ee2ac2382807e44c70fa705e16b807bc1f88393dae63d54978fe3725fecb922f9210ca833dd9aafee130e5cce727cc004e9c80e540ed55dfc95b4672f74b
+DIST tempest-46.2.0.tar.gz 1184257 BLAKE2B 3d220ab25417f8950154557b42c533de7d3828fb8328a6575be95ceb8c51c99d0bb010b26dd8f7a91f143200f0efd6c3f777e9da867a6b2dc8d281469b56c81b SHA512 a82dd8c71e6437e3f6b8b9f3fc21820d7f7ff975121a9ffcd672f9a73c9e67ef547d32cc10f55b76d71189d84cc181f90ca1ee49e88f0bc462c6caf2dc7c65e6
diff --git a/dev-python/tempest/tempest-46.2.0.ebuild b/dev-python/tempest/tempest-46.2.0.ebuild
new file mode 100644
index 0000000000000..c971dc63cfbd5
--- /dev/null
+++ b/dev-python/tempest/tempest-46.2.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/python-subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/testscenarios-0.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	stestr --test-path ./tempest/tests run --concurrency="$(makeopts_jobs)" ||
+		die "Tests failed for ${EPYTHON}"
+}