From b86d1d16df5887cafae990ef7d68f535fcc169b1 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Mon, 15 Sep 2025 04:04:02 +0200
Subject: [PATCH] dev-python/zstandard: Bump to 0.25.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/zstandard/Manifest                |  1 +
 dev-python/zstandard/zstandard-0.25.0.ebuild | 73 ++++++++++++++++++++
 2 files changed, 74 insertions(+)
 create mode 100644 dev-python/zstandard/zstandard-0.25.0.ebuild

diff --git a/dev-python/zstandard/Manifest b/dev-python/zstandard/Manifest
index a398128509904..31bd6ef05216f 100644
--- a/dev-python/zstandard/Manifest
+++ b/dev-python/zstandard/Manifest
@@ -1,2 +1,3 @@
 DIST python-zstandard-0.23.0.gh.tar.gz 732448 BLAKE2B 920b53dc4a221059411062229ddf0ff51c478c2212e5599dec21298fef8e30b7a160c2f7d958ef95251ce5fb1357eaf4a8c3e4eca37304ef7a43176f723f3394 SHA512 06d799f8c5e89e5cc2f5b8ff100aeb3c3ff938757ce39852affb075487f65406d7d3f6d611b1864ec025fff86a51bf15b80c8af6260beda050b4fef5b7edd206
 DIST python-zstandard-0.24.0.gh.tar.gz 751192 BLAKE2B 6bf54d96b3cbc06ff052fc3b1d373b745ac325dd61ee958c2dfa890533f0b164b23f5e9df0580525dab4c56920d48724a2614c05d8f06b1607fe31752063ea57 SHA512 9a06db18a3ac5d8583b5c28a27f93c9cb3310308a5cdf71df4324c442b1a2960d8df5ae47d38d765e6bb33e8f6d73ffad26f3c27d9649802a292f74d7933f00d
+DIST python-zstandard-0.25.0.gh.tar.gz 795455 BLAKE2B 6f5410b66b90cd737530259328d4abd04129a249f9b508db2e5ccd2cb028b22f13f0659b16604afe0f9c5026b282a0c5eb4a1faaa6df4946f9b99319d06ef825 SHA512 1ca492bcb39c22ec9eb1877799172de4a04033df364f4271b658243c0a9816ac584df0df85ebe967a2e2b98a10db90b66e7b050ecb8bfa9f9c7ad50f2f87921a
diff --git a/dev-python/zstandard/zstandard-0.25.0.ebuild b/dev-python/zstandard/zstandard-0.25.0.ebuild
new file mode 100644
index 0000000000000..af29b37637ba7
--- /dev/null
+++ b/dev-python/zstandard/zstandard-0.25.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1
+
+MY_P=python-zstandard-${PV}
+DESCRIPTION="Zstandard Bindings for Python"
+HOMEPAGE="
+	https://github.com/indygreg/python-zstandard/
+	https://pypi.org/project/zstandard/
+"
+SRC_URI="
+	https://github.com/indygreg/python-zstandard/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+DEPEND="
+	>=app-arch/zstd-1.5.7:=
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/cffi-1.14.0-r2:=[${PYTHON_USEDEP}]
+	' 'python*')
+"
+
+EPYTEST_PLUGINS=( hypothesis )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# the C backend is repeatedly broken, so force CFFI instead
+	sed -e '/PYTHON_ZSTANDARD_IMPORT_POLICY/s:default:cffi:' \
+		-i zstandard/__init__.py || die
+	# unbundle zstd
+	rm zstd/* || die
+	> zstd/zstd.c || die
+	# it does random preprocessing on that, so we can't use #include
+	local f
+	for f in zdict.h zstd.h zstd_errors.h; do
+		cp "${ESYSROOT}/usr/include/${f}" "zstd/${f}" || die
+	done
+	sed -i -e '/include_dirs/a    libraries=["zstd"],' make_cffi.py || die
+
+	distutils-r1_src_prepare
+
+	DISTUTILS_ARGS=(
+		--no-c-backend
+	)
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# unreliable, fails on x86
+		tests/test_data_structures.py::TestCompressionParameters::test_estimated_compression_context_size
+		# check for bundled zstd version, fails on other system zstd
+		tests/test_module_attributes.py::TestModuleAttributes::test_version
+	)
+
+	rm -rf zstandard || die
+	epytest
+}