From b8458bbf13d6c1d179e0fb4b7a1bfebdac893545 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sun, 5 Oct 2025 13:34:46 +0200
Subject: [PATCH] gnome-base/gnome-desktop: Bump to 44.4

Signed-off-by: Pacho Ramos <pacho@gentoo.org>
---
 gnome-base/gnome-desktop/Manifest             |  1 +
 .../gnome-desktop-44.4-r300.ebuild            | 74 +++++++++++++++++++
 .../gnome-desktop-44.4-r400.ebuild            | 67 +++++++++++++++++
 3 files changed, 142 insertions(+)
 create mode 100644 gnome-base/gnome-desktop/gnome-desktop-44.4-r300.ebuild
 create mode 100644 gnome-base/gnome-desktop/gnome-desktop-44.4-r400.ebuild

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index ae1b4d97c33aa..96cdb47991671 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-desktop-44.1.tar.xz 766784 BLAKE2B 319c0cb48617755b7a8ff03245cc58b96ba74aa5c880311e8f719d0e5f3febfb19744f37f7d6744b212048cb03ed36ae9d67e3b0e79f02a7afe10521d4635584 SHA512 a939793a6870693f132cabb6dd5f06d0f2744cf97a9dc4b7a2b04c9a5aa09aa56f2f6d7630199a42d0d4e539ae724b54b91d4f9fe9ea2f785d854c58b2d8dd5f
 DIST gnome-desktop-44.3.tar.xz 763284 BLAKE2B e363e329c37073117c36659404d904df4c0877bfc37d0dfb8cb0e3308aba084520361a74bd4138ad3223b7e4b90e2dd15614e511d105ad51d79d1100bb727a31 SHA512 6dc5b43615ea47c0a091aa0cd9e258096811f175874ef72cf585b85d4ea9c95febe50acd48b06643c8ec9d2ef5dc9262476e0ca67f0000b0eef9902dd3e1a906
+DIST gnome-desktop-44.4.tar.xz 763656 BLAKE2B bb14f37e5b5540e99f6d10a7a78feb127bc0988322890234e6fb548d0532bd237af2be565fc56a0772e9e6e3322512b1401b0a0d5decc3c5f65ba848600e0e56 SHA512 c93a800121a3b8cbc307a32ca689f55b0f2637d3079892f0a6b01e713025c3b960ccfef5403935d9903ba8f5dce5be4fab3d89029cc103c190a991326fd74797
diff --git a/gnome-base/gnome-desktop/gnome-desktop-44.4-r300.ebuild b/gnome-base/gnome-desktop/gnome-desktop-44.4-r300.ebuild
new file mode 100644
index 0000000000000..5d95ba38ee5a9
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-44.4-r300.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/20" # subslot = libgnome-desktop-3 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug +introspection seccomp systemd udev"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:4
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddesktop_docs=false
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		-Dgtk_doc=false
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=false
+		-Dlegacy_library=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	rm -r \
+		"${ED}"/usr/share/locale \
+		|| die
+}
diff --git a/gnome-base/gnome-desktop/gnome-desktop-44.4-r400.ebuild b/gnome-base/gnome-desktop/gnome-desktop-44.4-r400.ebuild
new file mode 100644
index 0000000000000..56126f688868a
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-44.4-r400.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="4/2" # subslot = libgnome-desktop-4 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gtk-doc seccomp systemd udev"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection]
+	>=gui-libs/gtk-4.4.0:4[introspection]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo
+	>=dev-libs/gobject-introspection-1.54:=
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+	!<gnome-base/gnome-desktop-${PV}:3
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+		-Dbuild_gtk4=true
+		-Dlegacy_library=false
+		-Dintrospection=true
+	)
+	meson_src_configure
+}