dev-python/ccdproc: initial import

Package-Manager: portage-2.2.27

dev-python/ccdproc/Manifest

@@ -0,0 +1 @@
+DIST ccdproc-0.3.3.tar.gz 646341 SHA256 4b460deec77cd6d6f8997a544af5db091a6ab8a36383d3249dab38b0cbd2c837 SHA512 c4733409d20dcaa2513c4c40d5205a34c31be6868774f03cddc230957c52bad33232503277fbf33396c16c05ec435646a625a32dac9c6fba4063fc52141c6521 WHIRLPOOL bbad6ef6987f0bb3495271b8dd66c44492ed15a011aaf75193410d4a33df0061c507eb8b3cb7b30a050e2a7e151ad638c85f1d12ed159d219c3892d98e79e0e2

dev-python/ccdproc/ccdproc-0.3.3.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Astropy affiliated package for reducing optical/IR CCD data"
+HOMEPAGE="https://github.com/astropy/ccdproc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+DOCS=( README.rst )
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

dev-python/ccdproc/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@gentoo.org</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    ccdproc is a AstroPy-affliated package for the basic reduction of
+    CCD images. It provides a framework for accounting for error propagation
+    and bad pixel tracking through the reduction steps.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">ccdproc</remote-id>
+  </upstream>
+</pkgmetadata>