dev-python/sqlalchemy: Bump to 1.2.9

dev-python/sqlalchemy/Manifest

@@ -9,3 +9,4 @@ DIST SQLAlchemy-1.2.0.tar.gz 5451303 BLAKE2B 273edad173583d47d6ebdb4d3efddddb6e8
 DIST SQLAlchemy-1.2.2.tar.gz 5460157 BLAKE2B 60c5066a2993d9878f5d3abec1a6a9a4d0a3dc5878df71baee895e5278b95696b775e16000da0ba4c2c358b0a90e70faff0b5733a4f00255b0ec0d605cdd07c6 SHA512 060ce803b8b621d51aa69100c598c424c36f051bdce1e2df3f4d837815f91cb55c4e089db5375b01832ec28bf42332311009c51c1b5e7aae92aea001ee880db5
 DIST SQLAlchemy-1.2.4.tar.gz 5555033 BLAKE2B 5301d365cf6462b8a61deb3f01dcf86897c0070fe80f570b91f94a02e1830088b558004d915d17589dfaea1e5fd382fdf88c44020f3b3b94974db773b5ed2db6 SHA512 a12d17f222cc5fc4360c439e19cae67a013af07e2c22b1f55511c4862d718578249e6bf83151eefe35957e530dbf18a565b08cded3a5e45dd21103201f4d24e8
 DIST SQLAlchemy-1.2.7.tar.gz 5571719 BLAKE2B 995c977cd5bf22b464e5316d579a3bd5b15f2c2600230c729381f3dbecd1dd6a728ee08d5e8afa8e212bdc7e5272d8723706daed1db0ec353e3b56f5b9c614d7 SHA512 c592916dae177bcda7b3d7111af4269815d555273b548e35b58caaf518f7a5dc2256e5b98601cbbf0bbc95405fadd89f8e6b977e0d8104ce4e216d5c6924eda2
+DIST SQLAlchemy-1.2.9.tar.gz 5606090 BLAKE2B 7aade70c37a6e9afb1e459c88ea0d1ef927541d3ff8c64a634f81ba871fb9d0d14841e1c7a1ed28c12cb7a4d84d6ede6bf132f54d47019967fec8acd55757c33 SHA512 88ef57b9e456d7047bd7b5fd9607c87a473a9917d662960b0614fbfc40891002309eda55e66e42a6a280c6d6e7e8e6921349901a19c1caaedace2d532b32af22

dev-python/sqlalchemy/sqlalchemy-1.2.9.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="sqlite?"
+
+inherit distutils-r1 eutils flag-o-matic
+
+MY_PN="SQLAlchemy"
+MY_P="${MY_PN}-${PV/_beta/b}"
+
+DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
+HOMEPAGE="http://www.sqlalchemy.org/ https://pypi.org/project/SQLAlchemy/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc examples +sqlite test"
+
+REQUIRED_USE="test? ( sqlite )"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		<dev-python/pluggy-0.7s[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable tests hardcoding function call counts specific to Python versions.
+	rm -r test/aaa_profiling || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS=${CFLAGS}
+		append-cflags -fno-strict-aliasing
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	# Create copies of necessary files in BUILD_DIR.
+	# https://bitbucket.org/zzzeek/sqlalchemy/issue/3144/
+	cp -pR examples sqla_nose.py setup.cfg test "${BUILD_DIR}" || die
+	pushd "${BUILD_DIR}" > /dev/null || die
+	if [[ "${EPYTHON}" == "python3.2" ]]; then
+		2to3 --no-diffs -w test || die
+	fi
+	# Recently upstream elected to make the testsuite also pytest capable
+	# "${PYTHON}" sqla_nose.py || die "Testsuite failed under ${EPYTHON}"
+	py.test --verbose test || die "Testsuite failed under ${EPYTHON}"
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/. )
+	use examples && dodoc -r examples
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "MySQL support" dev-python/mysql-python dev-python/mysql-connector-python
+	optfeature "mssql support" dev-python/pymssql
+	optfeature "postgresql support" dev-python/psycopg:2
+}