dev-python/astroplan: initial import

Package-Manager: portage-2.3.2

dev-python/astroplan/Manifest

@@ -0,0 +1 @@
+DIST astroplan-0.2.tar.gz 264623 SHA256 427d6a890ea7bc4df0b8d0a4b607d060e6e2b230fa1224a648217790d8c1cba7 SHA512 ab98402d2b0daf64aea4a10934c8e33097b92d3b7de9a2346fa3e318e672c85966c050f560bb3fc4c247e2fdd4c94a4b158d6a0dff6af9c83d6411613c663bd9 WHIRLPOOL 6ab4ca9daf2daa8a6a16b06b7287473f149cf3261b2ef35a8f29a24f67e7c0d32edeef59c03fd1fe77f3050670a4c9488b4defe6e417f4925581ca300ca6a8f1

dev-python/astroplan/astroplan-0.2.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Observation planning package for astronomers"
+HOMEPAGE="https://astroplan.readthedocs.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+	  dev-python/sphinx[${PYTHON_USEDEP}]
+	  dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest-mpl[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${P}-ephem-import.patch )
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	echo 'backend: Agg' > "${WORKDIR}"/matplotlibrc || die
+	MATPLOTLIBRC="${WORKDIR}" virtx esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

dev-python/astroplan/files/astroplan-0.2-ephem-import.patch

@@ -0,0 +1,11 @@
+--- a/astroplan/conftest.py.orig	2016-11-30 23:17:49.057492656 +0000
++++ b/astroplan/conftest.py	2016-11-30 23:18:11.076451659 +0000
+@@ -38,7 +38,7 @@
+ try:
+     PYTEST_HEADER_MODULES['Astropy'] = 'astropy'
+     PYTEST_HEADER_MODULES['pytz'] = 'pytz'
+-    PYTEST_HEADER_MODULES['pyephem'] = 'pyephem'
++    PYTEST_HEADER_MODULES['pyephem'] = 'ephem'
+     PYTEST_HEADER_MODULES['matplotlib'] = 'matplotlib'
+     PYTEST_HEADER_MODULES['nose'] = 'nose'
+     PYTEST_HEADER_MODULES['pytest-mpl'] = 'pytest_mpl'

dev-python/astroplan/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@gentoo.org</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    Astroplan is an observation planning package for astronomers that can help
+    you plan for everything but the clouds.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">astroplan</remote-id>
+    <remote-id type="github">astropy/astroplan</remote-id>
+  </upstream>
+</pkgmetadata>