diff --git a/net-misc/tuba/Manifest b/net-misc/tuba/Manifest
index d6f32b07004c0..b39551e2bfad8 100644
--- a/net-misc/tuba/Manifest
+++ b/net-misc/tuba/Manifest
@@ -1 +1,2 @@
 DIST Tuba-0.10.3.gh.tar.gz 2848312 BLAKE2B 0ff29ebf7f37bea17d82e040b4e63c49acd03e6440017691ab1fae937f4ddfae944f67fc92f1eca71773d21787f692c39dfe8c8c1afecf723babdee7e30fca87 SHA512 3b7174f27e4b91b60868411909338d806a916cd7c4c47686c56eed68dcfda283ec6ab85ce4eebd1c392aecc3205c111d54f83e59fc66274256a19b0a004491f5
+DIST Tuba-0.11.0.gh.tar.gz 3624343 BLAKE2B e07258404505f10baf1ee8715e879bb0cdec7beb374ce20be63ce8e9866c61e05558d36966c540c7dceacf9a90e7f3a512f93ce8c98664a0d48daede8e770688 SHA512 0891e851cbbc2a3ee53efa20dd851f53f8a57a4d5fe1790ef907bd1586a5e3a85b3aab983d4cdb6e07fc4dc1df5cc2c712b7ade056e4d18e5e051965a5e60b03
diff --git a/net-misc/tuba/tuba-0.11.0.ebuild b/net-misc/tuba/tuba-0.11.0.ebuild
new file mode 100644
index 0000000000000..30decf597673c
--- /dev/null
+++ b/net-misc/tuba/tuba-0.11.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson optfeature vala
+
+MY_P=${P^}
+DESCRIPTION="Browse the Fediverse (GTK client)"
+HOMEPAGE="
+	https://tuba.geopjr.dev/
+	https://github.com/GeopJr/Tuba/
+"
+SRC_URI="
+	https://github.com/GeopJr/Tuba/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3 CC-BY-SA-4.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="exif gstreamer spell webkit"
+
+DEPEND="
+	app-crypt/libsecret[introspection,vala]
+	>=dev-libs/glib-2.80.0:2
+	dev-libs/icu:=
+	>=dev-libs/json-glib-1.4.4[introspection]
+	>=dev-libs/libgee-0.8.5:0.8[introspection]
+	dev-libs/libxml2:=
+	>=gui-libs/gtk-4.19:4[introspection]
+	>=gui-libs/libadwaita-1.8:1[introspection,vala]
+	>=gui-libs/gtksourceview-5.6.0:5[introspection,vala]
+	net-libs/libsoup:3.0[introspection,vala]
+	exif? (
+		>=media-libs/gexiv2-0.14:=[introspection,vala]
+	)
+	gstreamer? (
+		>=gui-libs/gtk-4.13.4:4[gstreamer,introspection]
+		media-libs/gstreamer[introspection]
+	)
+	spell? (
+		app-text/libspelling[vala]
+	)
+	webkit? (
+		net-libs/webkit-gtk:6
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	$(vala_depend)
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		# disable calling updaters (see pkg_post*)
+		-Ddistro=true
+		$(meson_feature spell spelling)
+		# not packaged
+		-Dclapper=disabled
+		$(meson_feature gstreamer)
+		$(meson_feature webkit in-app-browser)
+		$(meson_feature exif gexiv2)
+		-Dunifiedpush=disabled
+	)
+
+	vala_setup
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dosym dev.geopjr.Tuba /usr/bin/tuba
+}
+
+pkg_postinst() {
+	optfeature "WebP image support" gui-libs/gdk-pixbuf-loader-webp
+
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}