dev-debug/gfxreconstruct: Version bump to 1.4.328.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-debug/gfxreconstruct/Manifest

@@ -1,2 +1,4 @@
 DIST SPIRV-Reflect-1.4.321.0.tar.gz 326302 BLAKE2B 88b80b73c6ff49521351b02c1a077a98366db9b6fdc3e33553bedcda5efb5f89efebf18908e7034b904e9b09ae8c77d449bca9ce40ece8a06e2740ac2ce6dd0d SHA512 3fde31cf92a450b920c789995636dadb77e3f270acb6d26cc5f6905bf769d95297052009ada87deae16c36e3065ba0e300d7cfc9c0651f63555672b12d18f462
+DIST SPIRV-Reflect-1.4.328.0.tar.gz 347322 BLAKE2B e6921d260bc0672196881ed63f9340ad5f5b92df3bf5461f3fdb6712d93137711eb363b59c9a7b44ee186cbbe452e3b40473040e4725e632ad2637b7e96d5418 SHA512 0062021edd4694caf417674b3763f0a3361a29c29d399573579206c83054afbf3c999c08534bd234f818875b84711f3ce891ec2316949e29a8360c3c38ca079d
 DIST gfxreconstruct-1.4.321.0.tar.gz 48957387 BLAKE2B 67293e5d17b70753c1b7e9b6befc8c056fa0ba934b555fcf49c174866db9be04fa3fa1e278add19f9b7c85bb9455307c38d60cf78573ca2588546826c23df654 SHA512 9c90a4e18f1418a55a7e2d01d8a24bfde0af5470932325a37c34dbca646135583fea13090ec66fac84c054d77d7be63f59d55ad3f98948a9144377dbef0c97ba
+DIST gfxreconstruct-1.4.328.0.tar.gz 50582022 BLAKE2B 508a47879b469a5fb17feacb2a40113e7caca728c7fb6eccb6a7a0379f23f1e0f8601c89bce24239408c30c45e9c5904a19838433eed52ac344d23ae84775229 SHA512 66adaa1e6d696c82f78bd2e7041cac61c521b367440d342b47af922db2a7dec2721bbe12a171bd914be1ad9d544b89919b9ca102faa1080e2ff36ec99b782288

dev-debug/gfxreconstruct/gfxreconstruct-1.4.328.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+inherit cmake flag-o-matic
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/LunarG/gfxreconstruct.git"
+	EGIT_SUBMODULES=( external/{Vulkan-Headers,SPIRV-Headers,SPIRV-Reflect} )
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/LunarG/${PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz
+		https://github.com/KhronosGroup/SPIRV-Reflect/archive/vulkan-sdk-${PV}.tar.gz -> SPIRV-Reflect-${PV}.tar.gz
+	"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}"/${PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Graphics API Capture and Replay Tools"
+HOMEPAGE="https://github.com/LunarG/gfxreconstruct"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="wayland X"
+
+RDEPEND="
+	app-arch/lz4:=
+	app-arch/zstd:=
+	virtual/zlib:=
+
+	media-libs/vulkan-loader[wayland?,X?]
+	wayland? ( dev-libs/wayland )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-libs/libXrandr )
+"
+if [[ ${PV} != 9999* ]]; then
+	DEPEND+="
+		~dev-util/spirv-headers-${PV}
+		~dev-util/vulkan-headers-${PV}
+	"
+	PATCHES=(
+		"${FILESDIR}"/1.3.313.0-use-system-vulkan.patch
+	)
+fi
+
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		git-r3_src_unpack
+	else
+		default
+		rmdir "${S}"/external/SPIRV-Reflect || die
+		mv "${WORKDIR}"/SPIRV-Reflect-vulkan-sdk-${PV} "${S}"/external/SPIRV-Reflect || die
+	fi
+}
+
+src_configure() {
+	# -Werror=strict-aliasing
+	# https://bugs.gentoo.org/956019
+	# https://github.com/LunarG/gfxreconstruct/issues/2358
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_DISPLAY_SUPPORT=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DGFXRECON_ENABLE_OPENXR=OFF
+	)
+	cmake_src_configure
+}