dev-python/cryptography: 2.7 bump

Package-Manager: Portage-2.3.69, Repoman-2.3.17
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

dev-python/cryptography/Manifest

@@ -4,3 +4,4 @@ DIST cryptography-2.3.tar.gz 449464 BLAKE2B 7485c745f9c6512a5efce42181970deff19b
 DIST cryptography-2.4.2.tar.gz 468645 BLAKE2B 80ecde87cf1568239977fbe4f835db98f689a7dc3646d44229b5b33932885c288d4274427f5d04eb74e9e064b01b11b7eac40fc6221ea2241371bca618cc66df SHA512 800735fa86e9ad0f8517328d47e55dc79a2b86d8c7539ee2921c526085782d8dad5559bbee84f7effb42275503fa9a984b099a688c530c92f5672c423c0f1a28
 DIST cryptography-2.5.tar.gz 487694 BLAKE2B 9502e7b7987ee0101ad8e5fcd09208034222a7f20b6b3bc3126c8b59081c9d8ecf872985d5fca191fc132dd6759afd4d11c0e0d39268627f35990c005a2095d3 SHA512 5e8f8818fcaa8143526006b027107b8afbdc925d40c846701e65b2c7ee02235b7e0918246515520ef2030b1c87bb157d0d403c28ad68c31459d677af7e2d0b3f
 DIST cryptography-2.6.1.tar.gz 491580 BLAKE2B b81114b57e9973c80fe999a63a3b1269d6289ac67851fedc263927b74e9e5ec4f35356cf5d46e4a27a994d5a3b2b3b599fea264b3ebce3a0cac27abfde3ef046 SHA512 f14319e24d9dca52e74548cada5b78a6235f089ef875dbff4799e862f94da8b087f1b6e03e84dcef9fc7d7693c4a349c5f0cd54b8535806da777420ce8757d39
+DIST cryptography-2.7.tar.gz 495877 BLAKE2B 48654897ff6ecd2fcf732b2d0378b806a9162c07c9e8349128593f4e28b3df222ac6a9cc19bc9342d303d1930bfb12747f9831f2a1bc42b1e784d85d69f0bf00 SHA512 fa420f44b038b6fe1983c6f2c6d830e2668017c26e1e125ad621e37ea627a927ffe64d0e987e0a26dcc260834f2ec817cccd22da03b892190f46cb6e8131a5a8

dev-python/cryptography/cryptography-2.7.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Library providing cryptographic recipes and primitives"
+HOMEPAGE="https://github.com/pyca/cryptography/ https://pypi.org/project/cryptography/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 BSD )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="libressl idna test"
+
+# the openssl 1.0.2l-r1 needs to be updated again :(
+# It'd theb be able to go into the || section again
+#=dev-libs/openssl-1.0.2l-r1:0
+# the following is the original section, disallowing bindist entirely
+#!libressl? ( >=dev-libs/openssl-1.0.2:0=[-bindist(-)] )
+RDEPEND="
+	!libressl? (
+		dev-libs/openssl:0= (
+			|| (
+				dev-libs/openssl:0[-bindist(-)]
+				>=dev-libs/openssl-1.0.2o-r6:0
+			)
+		)
+	)
+	libressl? ( dev-libs/libressl:0= )
+	idna? ( >=dev-python/idna-2.1[${PYTHON_USEDEP}] )
+	>=dev-python/asn1crypto-0.21.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
+	virtual/python-enum34[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/cffi-1.8:=[${PYTHON_USEDEP}]' 'python*')
+	$(python_gen_cond_dep '!~dev-python/cffi-1.11.3[${PYTHON_USEDEP}]' 'python*')
+	test? (
+		~dev-python/cryptography-vectors-${PV}[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/iso8601[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-1.11.4[${PYTHON_USEDEP}]
+		!~dev-python/hypothesis-3.79.2[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.9.0[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( AUTHORS.rst CONTRIBUTING.rst README.rst )
+
+python_configure_all() {
+	append-cflags $(test-flags-CC -pthread)
+}
+
+python_test() {
+	py.test -v -v -x || die "Tests fail with ${EPYTHON}"
+}