diff --git a/dev-python/jsonschema-path/Manifest b/dev-python/jsonschema-path/Manifest
index 23f472ac79464..1db1964dc2cac 100644
--- a/dev-python/jsonschema-path/Manifest
+++ b/dev-python/jsonschema-path/Manifest
@@ -1 +1,2 @@
 DIST jsonschema-path-0.3.4.gh.tar.gz 40126 BLAKE2B cc7884ab41a0cdcfbd292831f9ed2a03f82af30f4482499c7940633741560228df59c4157457e8c44c57fb73f0f6142f10ad23d36f444fea71a84cf6309d953d SHA512 85b791a374d61bedf66a0ca44b6906ec74f02ffe991c1cb220267c85c0e7b493375d712d7ca0828681c9c15f170bc29d4b808b00778895fb13f1f7ff3cdf2a9c
+DIST jsonschema-path-0.4.0a1.gh.tar.gz 52038 BLAKE2B 2429946da29b4da31655018d93f5af474c7a5277f3dfacd9f26439f28e85d2b85225d0f2e5c68a254122cb4376fb9a7a969e81a2541e726c275f32fba579ce64 SHA512 285cd176127684975adc6f03eeb43b6297208761ec8dc5827ff1e60efb4be71fca18a8c1e9e29deb741a8a295b395b5e842c0350ff623fd363298216ec8072b9
diff --git a/dev-python/jsonschema-path/jsonschema-path-0.4.0_alpha1.ebuild b/dev-python/jsonschema-path/jsonschema-path-0.4.0_alpha1.ebuild
new file mode 100644
index 0000000000000..43c7ebc97eefa
--- /dev/null
+++ b/dev-python/jsonschema-path/jsonschema-path-0.4.0_alpha1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=${P/_alpha/a}
+DESCRIPTION="JSONSchema Spec with object-oriented paths"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema-path/
+	https://github.com/p1c2u/jsonschema-path/
+"
+SRC_URI="
+	https://github.com/p1c2u/jsonschema-path/archive/${PV/_alpha/a}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/pathable-0.5.0_beta1[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/referencing-0.28.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	# remove random pins
+	sed -i -e 's:\^:>=:' -e 's:<[0-9.]\+:*:' pyproject.toml || die
+	distutils-r1_src_prepare
+}