dev-python/elasticsearch-py: bump to 6.4.0

Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

dev-python/elasticsearch-py/Manifest

@@ -1,2 +1,3 @@
 DIST elasticsearch-oss-6.4.0.tar.gz 33727061 BLAKE2B dd0ff95bb124103ca340b480c5192c9919ef226d4c3ef1b61accd0df2ee9b60a8215693b3db0fa327a4d6791de66746654144a9172210687e8a2efa9f6f4dde3 SHA512 0197dcf24bdb81cbcfa492d899363528816143962abd1925a5092e8177c25e8ca490afe5868b41057b3cded296f59f38ed11ba0156a820b6c877c69a5888846c
 DIST elasticsearch-py-6.3.1.tar.gz 90047 BLAKE2B 765d0a34bd22067e07f4e862eb72f2b67bd0db3516abdf76cdc0d4f24de3db6941b4dbc6afb6315667d640514415cf08ff6de127c84ab36ef9bf062d4e687d55 SHA512 b975a6b446b760bf62289e855768a26b9e104aba9cd399cf275f59f2755efa00bd55c99a746751dad2f7a18f581a1b124c1bb9b91f5c3dc9fb00138c9d198aea
+DIST elasticsearch-py-6.4.0.tar.gz 97217 BLAKE2B 376768fab9bd7b4efd98f8cc24d4bad700f9bd2f9013a794e28986ee80463e5854399124bfde43a9a43d6773ee5e546fc28077452d2daab6e2e25810c045a986 SHA512 bb9a2fad3ca002b25fa58585cffdadf847a078f72a5b24297d58e1d598103cb38155ff61fd5802be8ccfec96daec3119ecb490f876c07263f103fbf26f6dc6d4

dev-python/elasticsearch-py/elasticsearch-py-6.4.0.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} pypy )
+ES_VERSION="6.4.0"
+
+inherit distutils-r1
+
+MY_PN=${PN/-py/}
+DESCRIPTION="Official Python low-level client for Elasticsearch"
+HOMEPAGE="https://github.com/elastic/elasticsearch-py"
+SRC_URI="https://github.com/elasticsearch/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	test? ( https://artifacts.elastic.co/downloads/elasticsearch/elasticsearch-oss-${ES_VERSION}.tar.gz )"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+# tests fail in chroot
+# https://github.com/elastic/elasticsearch/issues/12018
+RESTRICT="test"
+
+RDEPEND=">=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]"
+
+DEPEND="test? ( ${RDEPEND}
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	<dev-python/requests-3.0.0[${PYTHON_USEDEP}]
+	dev-python/nose[${PYTHON_USEDEP}]
+	dev-python/coverage[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	dev-python/nosexcover[${PYTHON_USEDEP}]
+	virtual/jre:1.8 )"
+
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-1.3.1-r1[${PYTHON_USEDEP}]"
+
+python_compile_all() {
+	emake -C docs -j1 man $(usex doc html "")
+}
+
+# FEATURES="test -usersandbox" emerge dev-python/elasticsearch-py
+python_test() {
+	ES="${WORKDIR}/elasticsearch-${ES_VERSION}"
+	ES_PORT="25124"
+	ES_INSTANCE="gentoo-es-py-test"
+	ES_LOG="${ES}/logs/${ES_INSTANCE}.log"
+	PID="${ES}/elasticsearch.pid"
+
+	# run Elasticsearch instance on custom port
+	sed -i "s/#http.port: 9200/http.port: ${ES_PORT}/g; \
+		s/#cluster.name: my-application/cluster.name: ${ES_INSTANCE}/g" \
+		"${ES}/config/elasticsearch.yml" || die
+
+	# start local instance of elasticsearch
+	"${ES}"/bin/elasticsearch -d -p "${PID}" -Epath.repo=/ || die
+
+	local i
+	local es_started=0
+	for i in {1..20}; do
+		grep -q "started" ${ES_LOG} 2> /dev/null
+		if [[ $? -eq 0 ]]; then
+			einfo "Elasticsearch started"
+			es_started=1
+			eend 0
+			break
+		elif grep -q 'BindException\[Address already in use\]' "${ES_LOG}" 2>/dev/null; then
+			eend 1
+			eerror "Elasticsearch already running"
+			die "Cannot start Elasticsearch for tests"
+		else
+			einfo "Waiting for Elasticsearch"
+			eend 1
+			sleep 2
+			continue
+		fi
+	done
+
+	[[ $es_started -eq 0 ]] && die "Elasticsearch failed to start"
+
+	export TEST_ES_SERVER="localhost:${ES_PORT}"
+	esetup.py test || die
+
+	pkill -F ${PID} || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	use examples && dodoc -r example
+	doman docs/_build/man/*
+	distutils-r1_python_install_all
+}