app-misc/todo: add 2.13.0

Signed-off-by: Ferenc Erki <erkiferenc@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/40324
Signed-off-by: Florian Schmaus <flow@gentoo.org>

app-misc/todo/Manifest

@@ -1 +1,2 @@
 DIST todo-2.12.0.tar.gz 716524 BLAKE2B 168951c50670228ba2e1438ec04f5907181073668f1e260874e48959f2e37d11ee7ba4f2b0e5e5c55c9375a31921eca258f720afe98d2a4841529ef6acbb1510 SHA512 3b30d5e395f878811831f57e8e1a040c990e1f042f57050b6381d83ffc8b92b1ce20bfd3c5aa8b5e028b4810a5b289599603b2e16efff8badac559d200ed79f5
+DIST todo-2.13.0.tar.gz 718852 BLAKE2B 33f5c8d3e6007da3a0d9b55ec3093079daad1c4771b3eeb1406484a610bccc91bb1d0bbd9951bae7e1ba78e0cf6e0c25a75a39d4ac05585620ee3139a7b5c209 SHA512 26a3135e29886b4536922e0b4fe35783f829c83d09a4a17dd855f602a3f38a3e028e287508da54d4c4d641525130f8a3caea962fe996bcd2294909b7ea2e59c6

app-misc/todo/todo-2.13.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1
+
+DESCRIPTION="A CLI-based TODO list manager"
+HOMEPAGE="http://todotxt.org"
+SRC_URI="https://github.com/todotxt/${PN}.txt-cli/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/${PN}.txt-cli-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-shells/bash"
+
+DOCS=( README.md LICENSE todo.cfg )
+
+src_prepare() {
+	default
+
+	# fix version string
+	sed -i -e "s/@DEV_VERSION@/${PV}/" todo.sh || die
+
+	# TODO_DIR variable is bogus
+	sed -i -e '/export TODO_DIR/d' todo.cfg || die
+	sed -i -e '4i export TODO_DIR="$HOME/.todo"' todo.cfg || die
+}
+
+src_install() {
+	dobin "${PN}.sh"
+	newbashcomp "${PN}_completion" "${PN}.sh"
+	einstalldocs
+}
+
+pkg_postinst() {
+	einfo
+	einfo 'Before starting todo, make sure to create'
+	einfo 'a .todo directory in your home directory:'
+	einfo '  $ mkdir -p $HOME/.todo'
+	einfo
+	einfo 'and make sure to copy the default todo'
+	einfo 'configuration file in the same location:'
+	einfo "  $ bzcat /usr/share/doc/${PF}/todo.cfg.bz2 > \$HOME/.todo/config"
+	einfo
+	einfo 'Alternatively, you can use XDG directories instead:'
+	einfo '  $ mkdir -p $HOME/.local/share/todo'
+	einfo '  $ mkdir -p $HOME/.config/todo'
+	einfo "  $ bzcat /usr/share/doc/${PF}/todo.cfg.bz2 > \$HOME/.config/todo/config"
+	einfo
+	einfo 'You can then edit this file as you see fit.'
+	einfo 'Enjoy!'
+	einfo
+	ewarn 'The Gentoo-specific todocli and todotxt aliases have been removed.'
+	ewarn 'If you still need them, add the following lines to your ~/.bashrc:'
+	ewarn
+	ewarn 'alias todocli=todo.sh'
+	ewarn 'complete -F _todo todocli'
+}