www-servers/tornado: Bump to 6.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

www-servers/tornado/Manifest

@@ -1 +1,2 @@
 DIST tornado-6.1.tar.gz 497359 BLAKE2B ed5981dec5cca962f907f97b7f906c1eef40d2b2b6d6cc16a21bd0a0a91ee58a60bea84b7ceeeff30b3462d707c56a5062c71d4ac8f25ca6a306ded6c6f072c5 SHA512 0ec1db1fad911182bda547c177a18b107b906cf66576443069e2b986cf041b3d4ebe08e5a168aa5cd3b56547f32f8b384bacaf74db89f582951d7b610b7494e8
+DIST tornado-6.2.tar.gz 504849 BLAKE2B 18fee464e043e20dcdd5677bc3a72949140a64ce353e09a21242fcade6d8b668517553c649d65e892d9c3fabacea96903d4e42b70676a62759900abc8f4a202f SHA512 157cbeee21bef29ac68b319329e7fc57db4c68dbb5a245e2171b7a28427ebbfe16b745e3bdbdec5912caae5eaa60c3cbbf8830c9c76fec5ffdf025e234468517

www-servers/tornado/tornado-6.2.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python web framework and asynchronous networking library"
+HOMEPAGE="
+	https://www.tornadoweb.org/
+	https://github.com/tornadoweb/tornado/
+	https://pypi.org/project/tornado/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
+	>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/sphinxcontrib-asyncio
+
+src_prepare() {
+	# Disable deprecation-warnings-as-errors because tornado has a lot of stuff deprecated in 3.10
+	sed 's/warnings.filterwarnings("error", category=DeprecationWarning, module=r"tornado\\..*")//' \
+		-i tornado/test/runtests.py || die
+	# broken upstream
+	sed -i -e 's:test_multi_line_headers:_&:' \
+		tornado/test/httpclient_test.py || die
+	# network-sandbox? ipv6?
+	sed -i -e 's:test_localhost:_&:' \
+		tornado/test/netutil_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x ASYNC_TEST_TIMEOUT=60
+	cd "${T}" || die
+	"${EPYTHON}" -m tornado.test.runtests --verbose ||
+		die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r demos/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}