dev-python/mox3: 0.24.0 bup

Package-Manager: Portage-2.3.19, Repoman-2.3.6

dev-python/mox3/Manifest

@@ -1,2 +1,3 @@
 DIST mox3-0.10.0.tar.gz 42424 BLAKE2B 124bb4525ed6d24ebf75037c1f049fc851d64bdf8eed29c26fcdabcfe5f6211aec7f16f5038b397978383bd11a81588b44aa790608bfdf5b8596daccf3230542 SHA512 1f56e17ae150339cb2f33dca065c246cf0ff2f633f182336a576e9ab0bd4512ec8f42a4cb128f38ede33fe7e796552768465cfc626abe4f734b7a06b4625710a
 DIST mox3-0.12.0.tar.gz 42377 BLAKE2B d6a841c8b28d47f21ae8e6f65abb7e2079762d45ccf670decf5815c5a2638af615804e711534ddb0ebbafdae6609f30e50ea20f224a7ccc5a02148f1ab0d23b6 SHA512 73e0215bf127589f791721a0cb9b8e3dcc379a23199339e370d641850a0a14c264eb9db94fbb37c99f9925ee3ebd302de14ec12fe1c8809dd3ca9c10cfd75468
+DIST mox3-0.24.0.tar.gz 44846 BLAKE2B dd1a27b20fc821de79f1e1f209872c3fb66f39b2330d1dda04c5b17045e337c84920e4538d7971f025d1377f9e91abd2fca8167508c5614fee06d9fca92aaa75 SHA512 6c081cf2b1e529f3213f7f48d22ed5d2980420b2de8f49607b624d5861f8b784f2f36d8a32fae3e81fe8186c1a9c36e6c4ec7d9de172c41c0530523590ef97b6

dev-python/mox3/mox3-0.24.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Mock object framework for Python"
+HOMEPAGE="http://www.openstack.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+CDEPEND=">=dev-python/pbr-1.8[${PYTHON_USEDEP}]"
+CRDEPEND=">=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}
+	test? (
+		${CRDEPEND}
+		>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+		>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/oslo-sphinx-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.6.2[${PYTHON_USEDEP}]
+		>=dev-python/openstackdocstheme-1.17.0[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	${CRDEPEND}
+"
+
+PATCHES=( "${FILESDIR}"/${P}-RegexTest-python3.6.patch )
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	rm -rf .testrepository || die "could not remove '.testrepository' under ${EPYTHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+
+	distutils-r1_python_install_all
+}