From ad85a2d854901f4a010f68017afafa37d5d097d0 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 26 Jan 2022 12:28:01 +0100
Subject: [PATCH] dev-python/appdirs: Use flit to ease bootstrap
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/appdirs/appdirs-1.4.4-r2.ebuild | 37 ++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 dev-python/appdirs/appdirs-1.4.4-r2.ebuild

diff --git a/dev-python/appdirs/appdirs-1.4.4-r2.ebuild b/dev-python/appdirs/appdirs-1.4.4-r2.ebuild
new file mode 100644
index 0000000000000..c65226ccfc69b
--- /dev/null
+++ b/dev-python/appdirs/appdirs-1.4.4-r2.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Module for determining appropriate platform-specific dirs"
+HOMEPAGE="https://github.com/ActiveState/appdirs"
+SRC_URI="https://github.com/ActiveState/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+src_configure() {
+	[[ -e pyproject.toml ]] &&
+		die "Upstream added pyproject.toml, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "appdirs"
+		dynamic = ["version", "description"]
+	EOF
+}
+
+python_test() {
+	"${PYTHON}" test/test_api.py -v || die "Tests fail with ${EPYTHON}"
+}