From ad3c5f28c60f32934406aa6be129feb7daf251bc Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 16 Mar 2025 22:26:09 +0100
Subject: [PATCH] kde-frameworks/knotifications: Drop IUSE phonon

... leaving media-libs/libcanberra, same as with KF6 already.

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../knotifications-5.116.0-r1.ebuild          | 48 +++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 kde-frameworks/knotifications/knotifications-5.116.0-r1.ebuild

diff --git a/kde-frameworks/knotifications/knotifications-5.116.0-r1.ebuild b/kde-frameworks/knotifications/knotifications-5.116.0-r1.ebuild
new file mode 100644
index 0000000000000..c6cac2c349a02
--- /dev/null
+++ b/kde-frameworks/knotifications/knotifications-5.116.0-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for notifying the user of an event"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv ~x86"
+IUSE="dbus qml speech X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5[X?]
+	media-libs/libcanberra
+	dbus? ( dev-libs/libdbusmenu-qt[qt5(+)] )
+	qml? ( >=dev-qt/qtdeclarative-${QTMIN}:5 )
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libXtst
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dbus dbusmenu-qt5)
+		$(cmake_use_find_package qml Qt5Qml)
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}