diff --git a/app-admin/awscli/Manifest b/app-admin/awscli/Manifest
index 5881b7ff99543..74b3c8708dffa 100644
--- a/app-admin/awscli/Manifest
+++ b/app-admin/awscli/Manifest
@@ -7,3 +7,4 @@ DIST aws-cli-1.40.38.gh.tar.gz 2951069 BLAKE2B d6e94b9adb54ba21e36a47fdf47f742e3
 DIST aws-cli-1.40.39.gh.tar.gz 2961319 BLAKE2B b90e2f3c19c0fa870b5ec0a670ab54ca6d8964a553a1dbbf6cd68be6b458ba4e0b05fa7c01dbe7b0fbbe2c13df9254752e4c1e351c0c1d9cd395abf42096912b SHA512 fe97d8d8d4f91717060dd2166260289a4690f846c08fe1799303f7602e1770d19b9b2c5b78a1448136ce4decb484af8cb0a63687cff51c06aaa361871bc7a435
 DIST aws-cli-1.40.40.gh.tar.gz 2961905 BLAKE2B 437b67a35d939bc1bc15203443ed2bd2ce19f4a652d40263460b0b322bffe4247f0ea72b09199d348fa3654abcabbf308ee976eadfdc7a4146afbc3bd9a90eab SHA512 b6a19cdc2edf2f65327e311357aba4374af2c9e630a6250488b21e12f82b0269689089a9f021afe11d6f77a018361a0044afba6de0af88c955c3792f290410bd
 DIST aws-cli-1.40.41.gh.tar.gz 2962210 BLAKE2B 4447e7d4564ce1fb1f5306bb6fc86e9075681a6b1d567ad5f40f0f131b0c9dfc5b27a8e1a2c97cb3f911a267c632ea3c6dcdf98632dfe031558c081791f5186b SHA512 ce1116d75b48f6a9cdf3f5fba83abe77cd70ff65d1cdb689da3749ab5a28c1895b77b6868ec6422b901203749ef5f5143e71d0323199aac2a8fff45cc762f944
+DIST aws-cli-1.40.42.gh.tar.gz 2964125 BLAKE2B 08d21bc5c84ad35ea4e6d30abab53d626338cb4537f9a118993c0d2422990942845b619055ae3ba5ee4bd6edd76366003abc511d97d178b804e0441f9d070fa5 SHA512 8d5a532f7517268c8d2796c88047aeaa294abc69c468fb5086d007e7962966cfd268cdf611701f81530c540c3fbe35db678369f5405186185adfa463708f2c64
diff --git a/app-admin/awscli/awscli-1.40.42.ebuild b/app-admin/awscli/awscli-1.40.42.ebuild
new file mode 100644
index 0000000000000..a5edb5c04bb24
--- /dev/null
+++ b/app-admin/awscli/awscli-1.40.42.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 shell-completion
+
+MY_P=aws-cli-${PV}
+DESCRIPTION="Universal Command Line Environment for AWS"
+HOMEPAGE="
+	https://github.com/aws/aws-cli/
+	https://pypi.org/project/awscli/
+"
+SRC_URI="
+	https://github.com/aws/aws-cli/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# botocore is x.(y-2).(z+1), sigh
+BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) - 2)).$(( $(ver_cut 3-) + 1 ))"
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/rsa[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.13.0[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	!app-admin/awscli-bin
+"
+BDEPEND="
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+	# strip overzealous upper bounds on requirements
+	sed -i -e 's:,<[=0-9.]*::' -e 's:==:>=:' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local serial_tests=(
+		tests/functional/ecs/test_execute_command.py::TestExecuteCommand::test_execute_command_success
+		tests/functional/ssm/test_start_session.py::TestSessionManager::test_start_session_{fails,success}
+		tests/functional/ssm/test_start_session.py::TestSessionManager::test_start_session_with_new_version_plugin_success
+		tests/unit/customizations/codeartifact/test_adapter_login.py::TestDotNetLogin::test_login_dotnet_sources_listed_with_backtracking
+		tests/unit/customizations/codeartifact/test_adapter_login.py::TestDotNetLogin::test_login_dotnet_sources_listed_with_backtracking_windows
+		tests/unit/customizations/codeartifact/test_adapter_login.py::TestNuGetLogin::test_login_nuget_sources_listed_with_backtracking
+		tests/unit/customizations/ecs/test_executecommand_startsession.py::TestExecuteCommand::test_execute_command_success
+		tests/unit/customizations/test_sessionmanager.py
+		tests/unit/test_compat.py::TestIgnoreUserSignals
+		tests/unit/test_help.py
+		tests/unit/test_utils.py::TestIgnoreCtrlC::test_ctrl_c_is_ignored
+	)
+	EPYTEST_XDIST= epytest "${serial_tests[@]}"
+
+	local EPYTEST_DESELECT=(
+		"${serial_tests[@]}"
+
+		# flaky (some ordering?)
+		tests/functional/s3/test_cp_command.py::TestCPCommand::test_multipart_upload_with_checksum_algorithm_crc32
+	)
+	# integration tests require AWS credentials and Internet access
+	epytest tests/{functional,unit}
+}
+
+python_install_all() {
+	newbashcomp bin/aws_bash_completer aws
+	newzshcomp bin/aws_zsh_completer.sh _aws
+
+	distutils-r1_python_install_all
+
+	rm "${ED}"/usr/bin/{aws.cmd,aws_bash_completer,aws_zsh_completer.sh} || die
+}
diff --git a/dev-libs/c-blosc2/Manifest b/dev-libs/c-blosc2/Manifest
index 862875629ff17..c063128e096cd 100644
--- a/dev-libs/c-blosc2/Manifest
+++ b/dev-libs/c-blosc2/Manifest
@@ -1,2 +1,3 @@
 DIST c-blosc2-2.17.1.gh.tar.gz 3292519 BLAKE2B 00adf947ed7f42bae807bb5b85f23e0be08df87ed0d05032e83b61726f520b542233672e9d5efc18dd842e509a67dfc49d6d5adccdb36cd5966a300fe754cc74 SHA512 f5f55cd7aecc397e57183e3000ccfef12544b69493d8f0d055ac18878d7b39b06a1c3ecacfef663b120b13170a822dce8e29c2903d18307b2fe30644826d88f7
 DIST c-blosc2-2.18.0.gh.tar.gz 3298036 BLAKE2B a5c072e7ec337b1ecc73e2d9a6fd5272af3c08200af52e3b539142eb1d26bf684669a3f97298173b5d281c97def0f91a4df2104e738e45db832b6d688a3b24aa SHA512 78c9795ba00fde0ac9e5831646984e11867a76a28bae9f9069afeffc8841d03ad31ff54b833ab183485260109aee872119a52403b31f579549701b87f84ba52d
+DIST c-blosc2-2.19.0.gh.tar.gz 3300743 BLAKE2B 44ef2150bf618c1bac1ff9000f6f12ae3e6310026a82eac6efb26bc96ef4e3c7ec40d59d18c75c4e801ede5acce14c71403b230ca436b4efa0db3550902bb490 SHA512 92a92f251666238e741970b1ec7a46213d0755543e29ee160a2b20ba0b36aade7cc8971e5df7ea1aefe62c32b765efbcd60b6b20d7f697f086f6004ed65bd2a1
diff --git a/dev-libs/c-blosc2/c-blosc2-2.19.0.ebuild b/dev-libs/c-blosc2/c-blosc2-2.19.0.ebuild
new file mode 100644
index 0000000000000..00ff5d98f4f1f
--- /dev/null
+++ b/dev-libs/c-blosc2/c-blosc2-2.19.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Blocking, shuffling and lossless compression library"
+HOMEPAGE="
+	https://www.blosc.org/c-blosc2/c-blosc2.html
+	https://github.com/Blosc/c-blosc2/
+"
+SRC_URI="
+	https://github.com/Blosc/c-blosc2/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0/4"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test +zlib +zstd"
+REQUIRED_USE="test? ( zlib zstd )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=app-arch/lz4-1.7.5:=
+	zlib? ( sys-libs/zlib:= )
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_configure() {
+	# remove bundled libs (just in case)
+	rm -rf internal-complibs || die
+
+	local mycmakeargs=(
+		-DBUILD_STATIC=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_BENCHMARKS=OFF
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_FUZZERS=OFF
+		-DDEACTIVATE_ZLIB=$(usex !zlib)
+		-DDEACTIVATE_ZSTD=$(usex !zstd)
+		-DPREFER_EXTERNAL_LZ4=ON
+		-DPREFER_EXTERNAL_ZLIB=ON
+		-DPREFER_EXTERNAL_ZSTD=ON
+
+		# force regular zlib, at least for  the time being
+		-DCMAKE_DISABLE_FIND_PACKAGE_ZLIB_NG=ON
+
+		# upstream overrides CMAKE_C_FLAGS, preventing ${CFLAGS} defaults
+		# from applying, https://github.com/Blosc/c-blosc2/issues/433
+		-DCMAKE_C_FLAGS="${CFLAGS}"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	# Tests fail in parallel, https://github.com/Blosc/c-blosc2/issues/432
+	MAKEOPTS=-j1 cmake_src_test
+}
diff --git a/dev-python/asgiref/asgiref-3.8.1.ebuild b/dev-python/asgiref/asgiref-3.8.1.ebuild
index c535857a255b1..93b9553cbd932 100644
--- a/dev-python/asgiref/asgiref-3.8.1.ebuild
+++ b/dev-python/asgiref/asgiref-3.8.1.ebuild
@@ -19,10 +19,5 @@ LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
-BDEPEND="
-	test? (
-		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
-	)
-"
-
+EPYTEST_PLUGINS=( pytest-asyncio )
 distutils_enable_tests pytest
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index f6c7a5086244d..2e80c78454b1b 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,3 +7,4 @@ DIST boto3-1.38.39.gh.tar.gz 958398 BLAKE2B dbbfc1635cc30103daa1dd7de197176bda4d
 DIST boto3-1.38.40.gh.tar.gz 958953 BLAKE2B 08c9f5406fecb3251b0c0f7bf6b67a80a1fbf4572f92d8b78f7bc0e56376064d47497b7e70377efcf9afe53e785eabc1f2b12ce74dd3fca47d56e1f717b9a56c SHA512 a503d55219797a34014b5378d4b58dbc6c134790222b34c3155fd80356395eafa2ca5ab3e75e7a3e717726a661223f9ef18c984b4004d0589daf123332df813f
 DIST boto3-1.38.41.gh.tar.gz 959656 BLAKE2B cf74e27c26735b9a02be41df7e077aed5e3df61fec3cef38fbf08e6b24bb23030579a92f28a717056a86d67251ce69aae82820c4d8af0d34f4d77076ebc45f1b SHA512 dc3110929ac801348f960c419d555160e315e3724101fc3ec551cb60520703fa77a4dd69744e99b8062402b0d53941aa5a7a006bece5a064de7491fbf2050a37
 DIST boto3-1.38.42.gh.tar.gz 959917 BLAKE2B e53b807906bf367b91e4826b6ef1ad7446bde55b4f0b73bb62d7d88a74037c05ec13150a2bbe8c3b4f372452f730bf9d3e36dcef411df8ea87b0c0185aed4201 SHA512 f4eb6aa1c9d8e2062a1e5825b9e2c8ae988f904c30ed0efe1e937ff90e223dc488c3340c0462433da217dce3106c9746577f4add8a8a7e160de63bf0e3cbad93
+DIST boto3-1.38.43.gh.tar.gz 961150 BLAKE2B 8e7472e9352cc0071867441586e49c8284d9dcd79a34ef03af5c2a8addbedb1d48c0adbb28937e3de081a1913a79ae9d03bd2e79bc9c98bdad93139458b726a3 SHA512 5d8280720ee9c8767cdf1229893f328154c26bf0e8e87831f54045a23a9e12be0fb315f3771e4f725eb8cbc431f84445beefd43843483beddb9386c051537f4f
diff --git a/dev-python/boto3/boto3-1.38.43.ebuild b/dev-python/boto3/boto3-1.38.43.ebuild
new file mode 100644
index 0000000000000..bd6e26787db4f
--- /dev/null
+++ b/dev-python/boto3/boto3-1.38.43.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.13.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index c1634498753c4..af29bfdd805ec 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,3 +7,4 @@ DIST botocore-1.38.39.gh.tar.gz 14778742 BLAKE2B 3d8533688317d05707e0cab26faebab
 DIST botocore-1.38.40.gh.tar.gz 14783063 BLAKE2B 2c5eeb4ea827b21409fe9b21e837e12245cebc0063246e8e89b9574dc722b52410202a0ff8043cd05401eff2f0132c9e25dc0bcb8bd293902e5c44b957eef1f5 SHA512 4bd2cbb6f9907e33bab222f7da725b8790dcb53e69a2da4552d5bd1cde637d5467ac607a2df946edb2de561c1c81c294ad7933d621ad182e6906192407a4fb3b
 DIST botocore-1.38.41.gh.tar.gz 14788068 BLAKE2B 3bc2cfb9e45235b076266a96fd3568753c267ab8a1ff438e21159c3d31cfa9f0c6b057ffda665006adacb69d75282c34f31d14095388ee120274dd60cc4e0f2d SHA512 de75b9799754cfa55fd54716ab088719f96403d2fc9b357751263f8382bb513f0526d9815cbff7c317fbd66508354e6024d622bd09d0bef035939f03f172a575
 DIST botocore-1.38.42.gh.tar.gz 14799205 BLAKE2B 9def6b5bda7f2c16610e6b2b3925cb4d6e22940e6b4f11c82969749af81532977a62549b4f480e792d09322695efd6688a819b55d10e6560716eb56bb41915eb SHA512 c7ca063f9edf984b02e93afb8ee569c723d13c8ec70f77a8cc376abd9665260cfd990d6e52f13cb34059aff4e572892d0fd4ab3a3819030d08deaebf986717f2
+DIST botocore-1.38.43.gh.tar.gz 14803790 BLAKE2B 7aa15b99588100652e084898316cb8e1e11d43ce83a1dcca7ec86303ac4af7db981dd90c63326c69d7ba80884a51a2ed7a5b05f58ed0a7d873550911cd8b7090 SHA512 02666e9997a8a95b286a71cdb9474e18c7c1e96fd519289f0652f5361c519fd4f25b2d92005f13446f91cb2b7f274d0430d75c9678db5da41353a5c3d740013f
diff --git a/dev-python/botocore/botocore-1.38.43.ebuild b/dev-python/botocore/botocore-1.38.43.ebuild
new file mode 100644
index 0000000000000..a931fcaefec4f
--- /dev/null
+++ b/dev-python/botocore/botocore-1.38.43.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/docutils/Manifest b/dev-python/docutils/Manifest
index 0bc139545cb7c..7449657682a91 100644
--- a/dev-python/docutils/Manifest
+++ b/dev-python/docutils/Manifest
@@ -1,3 +1,4 @@
 DIST docutils-0.21.2.tar.gz 2204444 BLAKE2B 727c2f97fc5835a0ffa62e38ea85af366cd89ad1eaec0b8af8b1f3b12e6cddfddb65161ba34f9109952d37ba2cf8985f3c3b6905ebb2ac1c9a984cce3fb4d170 SHA512 7fafa331f5687448e80d299c20cdccc4b49819fa471b5f586bf0ab18c694ba43a70f58e7c76b0a70a16267585548389214e11a4998ad7fdc19a27f0f7644539c
 DIST docutils-0.22rc2.tar.gz 2275875 BLAKE2B 62140304e9715e31d8be69c9b65fa382832805368cbf3c184b6319405f22d6c05a16b3b28b5444b4e498c21f4bb7baee8520ef80b445123341aaab7a6a6965d6 SHA512 fcb347d29315a5c2e9f070057962094457bdaf08693c1393a649ae24bab572be027c253deb98561c5cd5a27f2d1f994cf7dea63d0cb74c3a3993c4cea45e0a48
 DIST docutils-0.22rc3.tar.gz 2278230 BLAKE2B 650373b87230bc376c785becfbe2d61e2d67e561facd364f877bd580113223e39b42053b1b5fcab09990f0fc0be9f7aebaff0fc5fdb4fd524e6f45bc4de34a89 SHA512 7fa2cdceb818a69bc1b52ee16680ce23f9d15dc51b684097b479204611e2b320d778e32d5494f88543d77bc1424ee04628680610ed2dc1f5c0798a18b8da5cbd
+DIST docutils-0.22rc5.tar.gz 2279312 BLAKE2B b0473cddb656c0ebcba2177ac46b8c4d246902d646e8baa486df7e33556d88c8f659df6443adfe83efe5a00a7a642fc6ec01843b04f416c85b08b465fd1bc8f3 SHA512 60e98478f331959c55cc6c7bcc7ecb33c0f1a4d6760500ec6186a0d7f5b5c0140ebd690f86221418dcf7d4976ff9386a0f2a83d00d823f6d5dcb97d7b9917c2e
diff --git a/dev-python/docutils/docutils-0.22_rc5.ebuild b/dev-python/docutils/docutils-0.22_rc5.ebuild
new file mode 100644
index 0000000000000..d5ea86951ef59
--- /dev/null
+++ b/dev-python/docutils/docutils-0.22_rc5.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python Documentation Utilities (reference reStructuredText impl.)"
+HOMEPAGE="
+	https://docutils.sourceforge.io/
+	https://pypi.org/project/docutils/
+"
+
+# GPL-3+ only for emacs/rst.el
+LICENSE="BSD BSD-2 GPL-3+ PSF-2.4 public-domain"
+SLOT="0"
+
+RDEPEND="
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+"
+
+python_compile_all() {
+	# Generate html docs from reStructured text sources.
+
+	# Place html4css1.css in base directory to ensure that the generated reference to it is correct.
+	cp docutils/writers/html4css1/html4css1.css . || die
+
+	cd tools || die
+	"${EPYTHON}" buildhtml.py --input-encoding=utf-8 --no-datestamp \
+		--stylesheet-path=../html4css1.css, --traceback ../docs || die
+}
+
+src_test() {
+	cd test || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" alltests.py -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Install tools.
+	python_doscript tools/buildhtml.py
+}
+
+python_install_all() {
+	local DOCS=( *.rst )
+	local HTML_DOCS=( docs tools docutils/writers/html4css1/html4css1.css )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/license-expression/Manifest b/dev-python/license-expression/Manifest
index 1feb1d23ff6f4..5c684b443eed6 100644
--- a/dev-python/license-expression/Manifest
+++ b/dev-python/license-expression/Manifest
@@ -1 +1,2 @@
 DIST license-expression-30.4.1.gh.tar.gz 172977 BLAKE2B b09352eee9eac0292a0c1ed11381dfa20979ede10f1bddd794617b7cb414233bd872fa76820202ef18286fbbd6beec81c6a6ca0b9588ed40e00e33fb108948ea SHA512 862024b37e304269522b2cb1bca97ca02491bcd7c402c6e1522e0a275f86fe4ae5ec719c9bdb9bec0e883768a7d138883af04f49ffd7ec44f441c7dc1ca3230a
+DIST license-expression-30.4.2.gh.tar.gz 179378 BLAKE2B 776d67f2c44f77be1e3e1da29a4005c9a8cbc43d4e575b9dca37b3048316bd0b2c824c57f343d33f16ca69ccb5b66d6ac8a63ce5548276b462770c63cf4e6358 SHA512 bf1ae85a44b711632403688be062cb1886a9a7a4aa2e8ed59fcda4cb802c96d6204560b926cb698051a23d19a5da585c982c8cb0cedde482ccdd7dbb155d01d8
diff --git a/dev-python/license-expression/license-expression-30.4.2.ebuild b/dev-python/license-expression/license-expression-30.4.2.ebuild
new file mode 100644
index 0000000000000..7dc5c839afd72
--- /dev/null
+++ b/dev-python/license-expression/license-expression-30.4.2.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Parse, compare, simplify and normalize license expressions"
+HOMEPAGE="
+	https://pypi.org/project/license-expression/
+	https://github.com/aboutcode-org/license-expression/
+"
+SRC_URI="
+	https://github.com/aboutcode-org/license-expression/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/boolean-py-4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-4[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/minikanren/Manifest b/dev-python/minikanren/Manifest
index 688ff94ec6452..c81666caed190 100644
--- a/dev-python/minikanren/Manifest
+++ b/dev-python/minikanren/Manifest
@@ -1,2 +1,3 @@
 DIST kanren-1.0.3.gh.tar.gz 72998 BLAKE2B fcbc852d1dfeef4dbe0b4f2daa36fa87f8e6b597d6f8dc80d3197b8d151aa0ffa1234a2677b5c430e3431cf826ff44d1c8954f043d3a8976970f73d403ccb544 SHA512 913930d98c006e355f700087f00bb002e93a68c782b6a8cba003242747a8060789a113f380199124a1499beca8d8399df73db9a003a6719a90378db86b2fc166
 DIST kanren-1.0.4.gh.tar.gz 51385 BLAKE2B 1a998b17757f7586d71e9576daabb06868449920746487c88b05fc7a4cc847f035bfeeac78d8addbcf8d814aeb99cd02ddc15a3a0480abddbf5709d2841001c1 SHA512 ae71b7d33eeb05e4e828b3115fb79157f5cad2166845f7887079ba0ebfe6505dcec1835a8f45d8eae9c3d4cde41804eadd0bc426f211ddba48374b0a9709d2e2
+DIST kanren-1.0.5.gh.tar.gz 51391 BLAKE2B 2007374c9e0420b648fd031b3d00b2dcc65abe4888b0b32c61c0e1255599e997d68b8b9e0e670b6036246a6f795755734089f3639f3ddb931deff7e91eaee904 SHA512 cd738e378a2037172c9ed59649f98fa65ce32fa72b6761a9b7cd7f665ac3e0786c500f80e1adbf4a04ad282c5965e7a584c64c723c8bf233f1a910dd907290f4
diff --git a/dev-python/minikanren/minikanren-1.0.5.ebuild b/dev-python/minikanren/minikanren-1.0.5.ebuild
new file mode 100644
index 0000000000000..ed4dda723578b
--- /dev/null
+++ b/dev-python/minikanren/minikanren-1.0.5.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=kanren-${PV}
+DESCRIPTION="Relational programming in Python"
+HOMEPAGE="
+	https://pypi.org/project/miniKanren/
+	https://github.com/pythological/kanren/
+"
+SRC_URI="
+	https://github.com/pythological/kanren/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cons-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/etuples-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/logical-unification-0.4.1[${PYTHON_USEDEP}]
+	dev-python/multipledispatch[${PYTHON_USEDEP}]
+	dev-python/toolz[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/multidict/Manifest b/dev-python/multidict/Manifest
index 4920d54ae619d..29bdec4283cd1 100644
--- a/dev-python/multidict/Manifest
+++ b/dev-python/multidict/Manifest
@@ -1,4 +1,3 @@
 DIST multidict-6.2.0.gh.tar.gz 82115 BLAKE2B 37b509d409278396f52e39d63b671b3b447039f2f98fa6f1b80b1ff4189105ca5a80b9027e8fcfbb95734b3c5531c1fd4a0cbfd778cdfab85ea5c127fb735717 SHA512 211dfe4900d815be1365284e18183f82f34783b777cbca929e2f8468b6748e237825febe9baa7a6d3e2a97476a8c6e061d2d7d2de94c48a2c526809224379656
-DIST multidict-6.3.2.gh.tar.gz 104692 BLAKE2B 8e8ea4d8d03b41c45ba26eab12da5f7bb890b5c2e01727c9257e8caefbdc7b95f98500b16fcef5bcf23b4ac9bb48875992176214ad6fa976dbd0fb640a40f583 SHA512 aec44734a3255eefcce5f0bf037b465eb536f65860fe410f1c249042286471cee2933004a0380579a701475a63931ca6615cde85b0c840af70db87268e6e3f8a
-DIST multidict-6.4.3.gh.tar.gz 106392 BLAKE2B 63ee89cc0dec98cd453aa7323bc7ddd9c705dfabe877c5982fe1ace405f3f2b666e8b668fecafdf83866c797b58e548f7d558f493ba4291e5d857725d4f8b1aa SHA512 d4c267a58c86f8cc257583dfefab77095b54124d34cea310beddfbbb58a4337154846165bd259884fb22a19ee13e02dbba6e44d5486fc6b9d96415fa582a8f36
 DIST multidict-6.4.4.gh.tar.gz 107158 BLAKE2B 6fbe211f13810464b591d7198c0529c0d7443270b25b2358e10042721abc40feddbf8b7c0525f20810bed510fb50c8ffe3d2e29b0ff0711b4dd5337bb54ac46a SHA512 ccf07263672abfcaa44b4e1b89e82d7a2843da9805cfb52644f44363b196bb025427478e7cf355d1c2692a1713ccd612761939ac32e30c21f5ad2d99012435c5
+DIST multidict-6.5.1.gh.tar.gz 116424 BLAKE2B 4c438450a49e7f5a8b5ac49ff124e018aa7e62642ff39ec8b92f6c24e776f9c6ffbaa3d3e8ecafaeff96c8164291d52539a94eb6e286642c4332d3636f691a06 SHA512 7fa411d12b492a2f567c0228e5822200e711a9e1c221595f2a6d40ffaa2c870dfeb9d12f421495e66c2c95673efd7c3275cef9810b1404e7e6afccaac1b6c182
diff --git a/dev-python/multidict/multidict-6.3.2.ebuild b/dev-python/multidict/multidict-6.3.2.ebuild
deleted file mode 100644
index 9bbfaae5c2a84..0000000000000
--- a/dev-python/multidict/multidict-6.3.2.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} pypy3 pypy3_11 )
-
-inherit distutils-r1
-
-DESCRIPTION="multidict implementation"
-HOMEPAGE="
-	https://github.com/aio-libs/multidict/
-	https://pypi.org/project/multidict/
-"
-SRC_URI="
-	https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
-IUSE="+native-extensions"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
-	' 3.10)
-"
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# don't enable coverage or other pytest settings
-	sed -i -e '/cov/d' pytest.ini || die
-	distutils-r1_python_prepare_all
-}
-
-python_compile() {
-	if ! use native-extensions || [[ ${EPYTHON} == pypy3* ]]; then
-		local -x MULTIDICT_NO_EXTENSIONS=1
-	fi
-
-	distutils-r1_python_compile
-}
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		tests/test_multidict_benchmarks.py
-		tests/test_views_benchmarks.py
-	)
-
-	rm -rf multidict || die
-
-	local cext=--c-extensions
-	if ! use native-extensions || [[ ${EPYTHON} == pypy3* ]]; then
-		cext=--no-c-extensions
-	fi
-	epytest "${cext}"
-}
diff --git a/dev-python/multidict/multidict-6.4.3.ebuild b/dev-python/multidict/multidict-6.5.1.ebuild
similarity index 91%
rename from dev-python/multidict/multidict-6.4.3.ebuild
rename to dev-python/multidict/multidict-6.5.1.ebuild
index bcbf2916832d6..d074c4aabdd68 100644
--- a/dev-python/multidict/multidict-6.4.3.ebuild
+++ b/dev-python/multidict/multidict-6.5.1.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~x64-macos"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
 IUSE="+native-extensions"
 
 BDEPEND="
@@ -30,6 +30,7 @@ BDEPEND="
 	)
 "
 
+EPYTEST_PLUGINS=()
 distutils_enable_tests pytest
 
 python_prepare_all() {
diff --git a/dev-python/numpydoc/Manifest b/dev-python/numpydoc/Manifest
index 845c3cd8bd3fe..518ce3d3136f9 100644
--- a/dev-python/numpydoc/Manifest
+++ b/dev-python/numpydoc/Manifest
@@ -1 +1,2 @@
 DIST numpydoc-1.8.0.gh.tar.gz 90624 BLAKE2B 112274fa185bd48909a3fbe0cd2a98465f94b30207060234a396278e1802058224164fb6f3c492a6b1e76b7e0f7966ecaf6c592c96675e6e45fae044414f62c7 SHA512 d7ea64f1140395815e0d95697d1b855ba0a5f63fc99e8cf1fb7d240cd799be1958c2efd034cbec64c8b3b1742076c8b7db5a0ddc54af3ef39fc341ea0e3ec586
+DIST numpydoc-1.9.0.gh.tar.gz 91390 BLAKE2B a864a4ebddc7ddab11a4ab6ea949b96a6c2447f6e726867ed0f49aba09a29c51cb130d5b565feeaaa3fb3de8b4e24748fa604e77ff3def7ba0f17d601d8563ff SHA512 7ae73a5bbce11e674fe8ca16e8ddce7914498f97dc8ebe85c26ae0cf240299596c20a6915e3a547a394e0e3f9ae6e9ac0694a2de7baa34918df98f523a8bfdf0
diff --git a/dev-python/numpydoc/numpydoc-1.9.0.ebuild b/dev-python/numpydoc/numpydoc-1.9.0.ebuild
new file mode 100644
index 0000000000000..62098d5a6cdab
--- /dev/null
+++ b/dev-python/numpydoc/numpydoc-1.9.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Sphinx extension to support docstrings in Numpy format"
+HOMEPAGE="
+	https://numpydoc.readthedocs.io/en/latest/
+	https://github.com/numpy/numpydoc/
+	https://pypi.org/project/numpydoc/
+"
+SRC_URI="
+	https://github.com/numpy/numpydoc/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/sphinx-6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/matplotlib-3.2.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# these require Internet (intersphinx)
+		numpydoc/tests/test_full.py::test_MyClass
+		numpydoc/tests/test_full.py::test_my_function
+		# TODO
+		numpydoc/tests/test_validate.py::test_extract_ignore_validation_comments
+	)
+	epytest -o addopts= --pyargs numpydoc
+}
diff --git a/dev-python/python-dotenv/Manifest b/dev-python/python-dotenv/Manifest
index 46c655868e285..7f6c6b00725ff 100644
--- a/dev-python/python-dotenv/Manifest
+++ b/dev-python/python-dotenv/Manifest
@@ -1 +1,2 @@
 DIST python_dotenv-1.1.0.tar.gz 39920 BLAKE2B 63509d9b31d42564ba5f477c61de26d02cfee30881a4d16928f287de1f67b81da0a6d9382f9d04a218d8f51e0a695f0ef0b5b251a40a29ed94c138408b304f7e SHA512 453f1262d330e1783dae1ef2ac18b998f817203c10705a974b294b79316a4cee68433622b4fa0aff2efed45e5fad04ec1fa4d15434ec1fc57c1c73a2518ef396
+DIST python_dotenv-1.1.1.tar.gz 41978 BLAKE2B 730cc1c4e32af4c22664c6ba2ebd93d5fe4b941bac8ec0387d0badf88f9ef84d6c9ae1807396ae8481765c13e70bb5c020e36368442f8d403ce884a8abedbd11 SHA512 c19d427f845ccdeacfdcd312e340139b9744ec3e8874b06b78b3f7b49e43b1024dd4dc85c5d7d79e65308c2924232729cb6a10301dd6f49142e2574956b2c14d
diff --git a/dev-python/python-dotenv/python-dotenv-1.1.1.ebuild b/dev-python/python-dotenv/python-dotenv-1.1.1.ebuild
new file mode 100644
index 0000000000000..d595e8e044b51
--- /dev/null
+++ b/dev-python/python-dotenv/python-dotenv-1.1.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Manage .env files"
+HOMEPAGE="
+	https://github.com/theskumar/python-dotenv/
+	https://pypi.org/project/python-dotenv/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		>=dev-python/click-5[${PYTHON_USEDEP}]
+		>=dev-python/sh-2[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( CHANGELOG.md README.md )
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o tmp_path_retention_policy=all
+}
+
+python_install() {
+	distutils-r1_python_install
+	ln -s dotenv "${D}$(python_get_scriptdir)"/python-dotenv || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Avoid collision with dev-ruby/dotenv (bug #798648)
+	mv "${ED}"/usr/bin/{,python-}dotenv || die
+}
diff --git a/dev-python/retrying/Manifest b/dev-python/retrying/Manifest
index 0c7954968126a..213b66cace659 100644
--- a/dev-python/retrying/Manifest
+++ b/dev-python/retrying/Manifest
@@ -1,2 +1,4 @@
 DIST retrying-1.3.4.gh.tar.gz 11789 BLAKE2B 8a75a007bfc8333592aa1aed5b7090a44264a3ad46b71d8a494a0033ce94059751e8276c383c7567da8487230ab2877368bed4b15dca6c45cff2d709eebfd6b4 SHA512 80bd19eefdbd8277ec0ba656d1b1d3589b2e3492cbb902c963376b3df475abbe4725c9902426a1784e4dddbd57ea8bc51ea5925a0a72a6f5c11333893314f2c5
 DIST retrying-1.3.5.gh.tar.gz 12165 BLAKE2B 2c90fefc5397b3daf255189193df97b33c497b112ac13b24872a316aae4b459f93c750ef13c1d07ac0980755e0dcdcb9530c6c4947632d3198bf95a6ecaffbc8 SHA512 87ce6a08861cff34022ed39525a84aab73eb62415aab1334ae8433dd1c3e65b13402eeffc8001d5249abfa9b864c658f00af95ff88db3b30f16e8ec50245a543
+DIST retrying-1.3.6.gh.tar.gz 12186 BLAKE2B dc7f95f2f8a6a23f0ef27218f2b99fb71728c0288923e4528e88c1d4459d3e35d56a6c53a2c6c58122606b68fb0b0ca25bc0298fcebf67097b7193eff7af1be9 SHA512 6980d0a1955092401fe890761ad151e6acfd17fabcac82d8846945877f6b23d2bf795a07c7aadef93bbfe22f3c856da1492f92b00ef1848720ba923814212660
+DIST retrying-1.4.0.gh.tar.gz 12224 BLAKE2B 796f6792eb581b2b426dcbdff57738e32340b12b962e24e362bd7d094063fd9dc9ad55428a476f3d12126660c506c5595a50d690a55ff06dbb100bd2b257ace0 SHA512 8b018c3f253835de40d568410f8c7ae14813bd1616cf8ad3b1d8b47b34359fc9c669958f60c94af3d32961a1369888c531f588a05d0b8af519b357c5ec954c4a
diff --git a/dev-python/retrying/retrying-1.3.6.ebuild b/dev-python/retrying/retrying-1.3.6.ebuild
new file mode 100644
index 0000000000000..d836a28f50d8f
--- /dev/null
+++ b/dev-python/retrying/retrying-1.3.6.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="General-purpose retrying library"
+HOMEPAGE="
+	https://github.com/groodt/retrying/
+	https://pypi.org/project/retrying/
+"
+SRC_URI="
+	https://github.com/groodt/retrying/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
diff --git a/dev-python/retrying/retrying-1.4.0.ebuild b/dev-python/retrying/retrying-1.4.0.ebuild
new file mode 100644
index 0000000000000..d836a28f50d8f
--- /dev/null
+++ b/dev-python/retrying/retrying-1.4.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="General-purpose retrying library"
+HOMEPAGE="
+	https://github.com/groodt/retrying/
+	https://pypi.org/project/retrying/
+"
+SRC_URI="
+	https://github.com/groodt/retrying/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
diff --git a/dev-python/sphinx-prompt/Manifest b/dev-python/sphinx-prompt/Manifest
index 71b542fcd68f6..3a5c1b82b8c2d 100644
--- a/dev-python/sphinx-prompt/Manifest
+++ b/dev-python/sphinx-prompt/Manifest
@@ -1 +1,2 @@
+DIST sphinx-prompt-1.10.0.gh.tar.gz 34718 BLAKE2B 463c3320e96b02336bc0b726cee6be1458ddccf61b484083f1694db9d00807650c555e1969a31e13c1e7ed8a92783d9275e7b54766d9e5ae77e617187debb4b5 SHA512 2253896d64a03598743268d3433321032911ce25a40d8a950750fcbd6586425e049c309116bc46b3cb982166f313b579b81dcd0087c8036a55f85d26e1d58cc6
 DIST sphinx-prompt-1.9.0.gh.tar.gz 39458 BLAKE2B 16b646bd0e288da3d2f401650c3131c7c6b9fb27023617717821927c7bd8b8d031f14d82b7dd02c6603f3ece084e766a28022cc418867646d770886cdce538ce SHA512 f9ee34b86ead0eda791ba7d648ae54785c09ca276279197c4632963892a03080e547d1930743d81ddb3b327c912c70a58dea968b1da763c4875ec84014b207f8
diff --git a/dev-python/sphinx-prompt/sphinx-prompt-1.10.0.ebuild b/dev-python/sphinx-prompt/sphinx-prompt-1.10.0.ebuild
new file mode 100644
index 0000000000000..7455649b4fe68
--- /dev/null
+++ b/dev-python/sphinx-prompt/sphinx-prompt-1.10.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx directive to add unselectable prompt"
+HOMEPAGE="
+	https://github.com/sbrunner/sphinx-prompt/
+	https://pypi.org/project/sphinx-prompt/
+"
+SRC_URI="
+	https://github.com/sbrunner/sphinx-prompt/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# version number relies on git repo, sigh
+	# also all dependencies are pinned to exact versions, sigh
+	sed -i \
+		-e "/^version =/s:[0-9.]\+:${PV}:" \
+		-e '/^\[tool\.poetry\.dependencies\]$/,$s:"[0-9.]\+:"*:' \
+		pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-ruby/dry-monads/Manifest b/dev-ruby/dry-monads/Manifest
index 310bf084f8a08..7eb43902a489c 100644
--- a/dev-ruby/dry-monads/Manifest
+++ b/dev-ruby/dry-monads/Manifest
@@ -2,3 +2,4 @@ DIST dry-monads-1.6.0.tar.gz 77141 BLAKE2B 714b2a35b6136639e4b071f01dcdc01a83b44
 DIST dry-monads-1.7.1.tar.gz 77942 BLAKE2B dc2451d8d511f9dbdff74847220a2991af32f673a710d372309b7073923f3a3f073a75a7929ad71eb54e285b3c77b5b2ab55d34d620c117332a66f0d03ae2fb8 SHA512 d25549a10ba1ec78730331795cb6777c7793ee8c9a9edb17f2d9aa0250e930f5852c6fa9978198b550ce03272007131d77fa2b1f1b8155b92df00c214b73f167
 DIST dry-monads-1.8.2.tar.gz 85765 BLAKE2B c5dc178804507e18d18274610bb2044744388ff9f5cd95970c5605570c72726074713861dc2c6b4ca392299a807229bc2045ccc4fd8e57a4bc72c1d04384fae9 SHA512 59fe0a05e45a9c233fd36e92067ca83dc0d8da839d645c3e27632b36b4f78d1f9f0a38cde42f88be82ca07cdc811505298ad6df32ba1b58bde34052513631fa5
 DIST dry-monads-1.8.3.tar.gz 85826 BLAKE2B 2201fef174119732a1b28cea6cb6d61e12c5538b40470537e61733a4a47dd04df35a84b0bb0ab404dd6460fddb538f03c9a482337afdf44c60bbbb5ed6acdbc5 SHA512 603e15dfe196db5af2ba5e54c264a6363fbc109aafba3cd14f27ce841f48f6b257dd7e79e72d8887f1458cd1b51138d670021117bb5cbc9086928437add506ad
+DIST dry-monads-1.9.0.tar.gz 87440 BLAKE2B f666de965bbe2226da4658edb388a5ff528dfdaae25f3deba113ac20401b483df52c1b5006f78ebe29413b8b1489e128e62861c32743fe8c9388f2ba41eeb414 SHA512 c1a4223b613173c75707fa7788e71c5be7653a17348eb358b71f1c6f8551ff283e668dfd244159388cd9af43febbef52f825dbc64a0d33900cb7b3747e2fe253
diff --git a/dev-ruby/dry-monads/dry-monads-1.9.0.ebuild b/dev-ruby/dry-monads/dry-monads-1.9.0.ebuild
new file mode 100644
index 0000000000000..68a492c077e32
--- /dev/null
+++ b/dev-ruby/dry-monads/dry-monads-1.9.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="dry-monads.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Common monads for Ruby"
+
+HOMEPAGE="https://dry-rb.org/gems/dry-monads/"
+SRC_URI="https://github.com/dry-rb/dry-monads/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="MIT"
+
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+
+ruby_add_rdepend "
+	dev-ruby/concurrent-ruby:1
+	>=dev-ruby/dry-core-1.1:1
+	>=dev-ruby/zeitwerk-2.6:2
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/dry-types
+	dev-ruby/warning
+)"
+
+all_ruby_prepare() {
+	# Avoid specs for unpackaged optional super_diff.
+	rm -f spec/extensions/super_diff_spec.rb || die
+}
diff --git a/dev-ruby/jwt/Manifest b/dev-ruby/jwt/Manifest
index d33bbea7ebffe..64885e4ee30c5 100644
--- a/dev-ruby/jwt/Manifest
+++ b/dev-ruby/jwt/Manifest
@@ -1,3 +1,4 @@
 DIST jwt-2.10.1.tar.gz 88211 BLAKE2B 765f166ef7bbde77c47e66e04778ab6ad0f2d66aaa2b79deb153117488c171cf655f5660d96a6f2aaa7887f699d1527eb6ff2ba93465533547f6a86259d66ae8 SHA512 f7ad9597d83c26af110f48217494f606362f33947f9ffeb1219c9c5b412b6ab5098a4ccb9198648b0bf5f9bcc79d3435ee339504411f3c32cd0c2b104fa2c73e
 DIST jwt-3.0.0.tar.gz 84987 BLAKE2B 18ee595e21c58a3f23f94469d707e7216e4a083b7f44ace3d9fff67484843b0cba0c209dc3b1d9f47622be6dafd2e3ae6694ff8e6b6dbae5800fdbee10c16924 SHA512 5769479aea0e7adbf92aee01220d657c89cf16e709e57d1ecefd81faa0fd5a0dc4e452ed6b3c742266021748787153307de20baeed365234471dcaf93b9118d5
 DIST jwt-3.1.0.tar.gz 87026 BLAKE2B 45547002de87558770c144e45a4d8b576237657cacf37dc699701e2e7bdba16b1add57212aa8b249b3157a85ef29024fc84f2e3cc97b387d0684785f2b6600c9 SHA512 e6fd3d4b4a07c959dbda8291b6f2ce5249809ef978392652b7874e93dee3f1511787f3f8d6b825602a47910d2c8684b1c8ac74d72c5a2c5a9bd9dc1b2e0c358e
+DIST jwt-3.1.1.tar.gz 87604 BLAKE2B 446df145ebf59494cb04080627faa4eb37b9eb558f95033b8981d2843b3c54d6b4ecb4ab58393672dd7dab09c065cb57ebe314d21209fc7a701a87e59ff4d78d SHA512 53d777081469779a30bdf56bc433331ba779033a06937de813adcf883184ed3afc41ef17b1b9e0e2195e170c6e4683fc19e3c2039339dc1d13fa2b0d43eb1566
diff --git a/dev-ruby/jwt/jwt-3.1.1.ebuild b/dev-ruby/jwt/jwt-3.1.1.ebuild
new file mode 100644
index 0000000000000..9a4598c03dd61
--- /dev/null
+++ b/dev-ruby/jwt/jwt-3.1.1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_GEMSPEC="ruby-jwt.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Ruby implementation of JSON Web Token draft 06"
+HOMEPAGE="https://github.com/jwt/ruby-jwt"
+SRC_URI="https://github.com/jwt/ruby-jwt/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+
+RUBY_S="ruby-jwt-${PV}"
+
+ruby_add_rdepend "dev-ruby/base64"
+
+ruby_add_bdepend "test? ( dev-ruby/logger )"
+
+all_ruby_prepare() {
+	sed -i -e "/simplecov/ s:^:#:" \
+		-e '/^SimpleCov.start/,/^end/ s:^:#:' \
+		spec/spec_helper.rb || die
+
+	sed -i -e 's/git ls-files -z/find * -print0/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
diff --git a/eclass/distutils-r1.eclass b/eclass/distutils-r1.eclass
index ba97a95f5798c..b9366d1875556 100644
--- a/eclass/distutils-r1.eclass
+++ b/eclass/distutils-r1.eclass
@@ -561,6 +561,20 @@ distutils_enable_tests() {
 				test_pkgs+=' dev-python/pytest-xdist[${PYTHON_USEDEP}]'
 			fi
 
+			local plugin
+			_set_epytest_plugins
+			for plugin in "${EPYTEST_PLUGINS[@]}"; do
+				case ${plugin} in
+					pkgcore)
+						plugin=sys-apps/${plugin}
+						;;
+					*)
+						plugin=dev-python/${plugin}
+						;;
+				esac
+				test_pkgs+=" ${plugin}[\${PYTHON_USEDEP}]"
+			done
+
 			if [[ ! ${DISTUTILS_SINGLE_IMPL} ]]; then
 				test_deps+=" ${test_pkgs//'${PYTHON_USEDEP}'/${PYTHON_USEDEP}}"
 			else
diff --git a/eclass/python-utils-r1.eclass b/eclass/python-utils-r1.eclass
index 840b820d00569..4ce75b962957f 100644
--- a/eclass/python-utils-r1.eclass
+++ b/eclass/python-utils-r1.eclass
@@ -1273,6 +1273,78 @@ _python_check_occluded_packages() {
 # parameter, when calling epytest.  The listed files will be entirely
 # skipped from test collection.
 
+# @ECLASS_VARIABLE: EPYTEST_PLUGINS
+# @DEFAULT_UNSET
+# @DESCRIPTION:
+# An array of pytest plugin package names (without categories) to use
+# for the package.  It has a twofold purpose:
+#
+# 1. When set prior to calling distutils_enable_tests, it causes
+#    dependencies on the specified pytest plugins to be added.
+#
+# 2. When plugin autoloading is disabled, it causes "-p" arguments
+#    loading specified plugins to be added.
+#
+# Defaults to an empty list.
+#
+# The eclasses explicitly handle a number of pytest plugins, and assume
+# the default of "dev-python/${package}" and "-p ${package}" for others.
+# If this is incorrect for some plugin package, please report a bug
+# to have it added.
+#
+# This is not a perfect solution, and may not be sufficient for some
+# packages.  In these cases, either plugin autoloading should be used
+# or PYTEST_PLUGINS environment variable may be used directly (see
+# pytest documentation).
+#
+# For pytest-timeout and pytest-xdist plugins, it is generally
+# preferable to use EPYTEST_TIMEOUT and EPYTEST_XDIST options
+# that handle passing all needed options.
+
+# @ECLASS_VARIABLE: EPYTEST_PLUGIN_AUTOLOAD
+# @DEFAULT_UNSET
+# @DESCRIPTION:
+# If set to a non-empty value, permits pytest plugin autoloading.
+# Otherwise, PYTEST_DISABLE_PLUGIN_AUTOLOAD=1 is set to disable it.
+#
+# If EPYTEST_PLUGINS is set explicitly or EAPI is 9 or later,
+# defaults to disabled.  Otherwise, defaults to enabled.
+# The recommended way to disable it in EAPI 8 or earlier is to set
+# EPYTEST_PLUGINS (possibly to an empty array).
+
+# @FUNCTION: _set_epytest_plugins
+# @INTERNAL
+# @DESCRIPTION:
+# Check if EPYTEST_PLUGINS is set correctly, and set the default
+# if it is not.
+_set_epytest_plugins() {
+	debug-print-function ${FUNCNAME} "$@"
+
+	# TODO: drop BASH_VERSINFO check when we require EAPI 8
+	if [[ ${BASH_VERSINFO[0]} -ge 5 ]]; then
+		[[ ${EPYTEST_PLUGINS@a} == *a* ]]
+	else
+		[[ $(declare -p EPYTEST_PLUGINS) == "declare -a"* ]]
+	fi
+	if [[ ${?} -eq 0 ]]; then
+		# EPYTEST_PLUGINS set explicitly -- disable autoloading
+		: "${EPYTEST_PLUGIN_AUTOLOAD:=}"
+	else
+		if ! declare -p EPYTEST_PLUGINS &>/dev/null; then
+			# EPYTEST_PLUGINS unset -- default to empty.
+			# EPYTEST_PLUGIN_AUTOLOAD default depends on EAPI.
+			EPYTEST_PLUGINS=()
+			if [[ ${EAPI} != [78] ]]; then
+				: "${EPYTEST_PLUGIN_AUTOLOAD:=}"
+			else
+				: "${EPYTEST_PLUGIN_AUTOLOAD:=1}"
+			fi
+		else
+			die 'EPYTEST_PLUGINS must be an array.'
+		fi
+	fi
+}
+
 # @ECLASS_VARIABLE: EPYTEST_TIMEOUT
 # @DEFAULT_UNSET
 # @DESCRIPTION:
@@ -1324,6 +1396,9 @@ epytest() {
 	local color=yes
 	[[ ${NO_COLOR} ]] && color=no
 
+	mkdir -p "${T}/pytest-xml" || die
+	local junit_xml=$(mktemp "${T}/pytest-xml/${EPYTHON}-XXX.xml" || die)
+
 	local args=(
 		# verbose progress reporting and tracebacks
 		-vv
@@ -1345,9 +1420,79 @@ epytest() {
 		# we don't need to preserve them
 		-o tmp_path_retention_count=0
 		-o tmp_path_retention_policy=failed
+		# write a junit .xml file to aid machine processing of results
+		--junit-xml="${junit_xml}"
+		# use xunit1 format as that includes an explicit path
+		-o junit_family=xunit1
 	)
 
-	if [[ ! ${PYTEST_DISABLE_PLUGIN_AUTOLOAD} ]]; then
+	if has_version ">=dev-python/pytest-8.4.0"; then
+		args+=(
+			# do not repeat (potentially multi-line) exception messages
+			# in the "short summary" section to make it more readable;
+			# we have them in the backtraces anyway
+			--force-short-summary
+		)
+	fi
+
+	_set_epytest_plugins
+	if [[ ! ${EPYTEST_PLUGIN_AUTOLOAD} ]]; then
+		local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	fi
+
+	if [[ ${PYTEST_DISABLE_PLUGIN_AUTOLOAD} ]]; then
+		local plugin
+		for plugin in "${EPYTEST_PLUGINS[@]}"; do
+			case ${plugin} in
+				# special cases
+				hypothesis)
+					plugin=hypothesispytest
+					;;
+				noseofyeti)
+					plugin=nose_of_yeti
+					;;
+				pytest-helpers-namespace)
+					plugin=helpers_namespace
+					;;
+				pytest-lazy-fixtures)
+					plugin=pytest_lazyfixture
+					;;
+				pytest-testinfra)
+					plugin=pytest11.testinfra
+					;;
+				# "generic" cases
+				betamax)
+					plugin=pytest-${plugin}
+					;;
+				pyfakefs)
+					plugin=pytest_${plugin}
+					;;
+				# pytest-x-y-z -> x-y-z
+				pytest-aiohttp         | pytest-asyncio  | pytest-check     | \
+				pytest-console-scripts | pytest-django   | pytest-env       | \
+				pytest-freezer         | pytest-home     | pytest-httpbin   | \
+				pytest-import-check    | pytest-localftpserver              | \
+				pytest-localserver     | pytest-plus     | pytest-recording | \
+				pytest-regressions     | pytest-repeat   | pytest-reraise   | \
+				pytest-rerunfailures   | pytest-reserial                    | \
+				pytest-shell-utilities | pytest-skip-markers                | \
+				pytest-subtests        | pytest-timeout  | pytest-tornasync | \
+				pytest-trio            | pytext-xdist    | pytest-xprocess  | \
+				pytest-xvfb                                                 )
+					plugin=${plugin#pytest-}
+					;;
+				# foo-bar-baz unchanged
+				pytest-datadir         | pytest-qt       | pytest-subprocess)
+					;;
+				# foo-bar-baz -> foo_bar_baz
+				*)
+					plugin=${plugin//-/_}
+					;;
+			esac
+
+			args+=( -p "${plugin}" )
+		done
+	else
 		args+=(
 			# disable the undesirable-dependency plugins by default to
 			# trigger missing argument strips.  strip options that require
diff --git a/media-gfx/fotema/Manifest b/media-gfx/fotema/Manifest
index e5f8c03a27a3d..d8e5121cc6a3c 100644
--- a/media-gfx/fotema/Manifest
+++ b/media-gfx/fotema/Manifest
@@ -1,7 +1,9 @@
 DIST fotema-1.20.1.gh.tar.gz 8953269 BLAKE2B 8ca66935e0be4be5f22384ad3f1e0c20f8a15b40a955d255b5ec6b93565f85b7ce1363ed7587a49b70d24dd2eaaa6ab7af8be5368d7bfc941a4883e82ac34adb SHA512 f7d3448105159e99f9b979bf97aff2e0adcf9abcb9c2a0aa70f914ac991b64b543a3bef0600feef1943a2c4da94936b9b66dfc0ee4f4eec59b40587fcc87d2a5
 DIST fotema-2.0.0.gh.tar.gz 8975137 BLAKE2B 03fdc71f4828c9b951f98b423f68c5529c55780c06956b132cb0fa44b77485cedbd3fd11a238c394c843043007e27a959a6e6d24a86efbe203942c39a2ddf577 SHA512 f2aa036be031950a41dd16647cf23487617f43bdcf4b109b819366924cea19b6b65ce32b67120f9906d77345bca9840ca8ceb1879c8c9963da212885b0441dfa
 DIST fotema-2.0.1.gh.tar.gz 8975210 BLAKE2B 2415f8d1e88a829372a0753fc1187bffa00eaffe1258834fb8a905cf757530b3e115611fd6eb9a4313a400d256eadce51d0e3407913d01cfa0c770c093821ae1 SHA512 eda74ebbc4301774ed58d8c1bf998e3b10df4b9961eaae5adffc1dfef58daea1085a1dc10d0bb58e0d1b22b1a4861389d3d1c65468a5ae3be64c5fb0845a2084
+DIST fotema-2.0.2.gh.tar.gz 8975274 BLAKE2B 231985d0b5d2e0eab27ae951226d0b10bd3e68a7f6388231d80a390768d8911b94fc74fb72cca5801d60e8ce0facd07dfd24f22eced1b4c3197032c7b5675931 SHA512 e86235940e45a5609e4c6984f4d36e0b050c742f0cc563d743347fc4dfeb0c2945f1b37401f00af2d216465b2118c4a57c5a6899ed4da8867b85f46f6f27eee2
 DIST fotema-rust-faces-43c0d5acd6f3f4d90c6487708f2e511a73bf7c9e.gh.tar.gz 839519 BLAKE2B 7ba344d55c5d108e63556dda32aaf60cfbd2b14a05e2965ca69e54e2aab578f6ba49f7a7b89d6c32cb5ace4b80f7a84247dcbb43a98d5d709895810798966b0b SHA512 aac99659e2d82d342f52b5860d9f1e284e1658fa9e0986b1c54a81cc33f6391535a2773d79defc6a7bf1e52591dc91d91a1ef3742c38e599baed79975b42de51
 DIST fotema-v1.20.1-crates.tar.xz 62319856 BLAKE2B 95406c2c6ca79267df0b02199822402b7aeb10f3241784b7952bec4e5d3938ee953adad93514d77f0cd0c83fe6db2fb75c4628007ccbbc3b99c7e4b57460618d SHA512 3f6a14e601813da00bae9963bb4bbdd66e0da5ebb7c5fff9f232d941ec103012d780b66ecbfa31e7cd423dfaa1fded03e72156e2bd7263e2389b4e12a8f314a3
 DIST fotema-v2.0.0-crates.tar.xz 61796908 BLAKE2B 729777dae5a9a684b808422c8bbbe07837b20f0bd2cbebbf10ddbdc46fe1af05fa1cf579fc7593689379ec33bb95f2151846cc6402dc3d75a0ffaa863420b142 SHA512 e96f9e6dfd90254580c9c91aeb83939a46fb210d21edf5c34d14c96191130c518cd44971d3c6267915bf06cb6f8b086ff8005093ae4a48d2efdf49b03392766c
 DIST fotema-v2.0.1-crates.tar.xz 61796908 BLAKE2B 729777dae5a9a684b808422c8bbbe07837b20f0bd2cbebbf10ddbdc46fe1af05fa1cf579fc7593689379ec33bb95f2151846cc6402dc3d75a0ffaa863420b142 SHA512 e96f9e6dfd90254580c9c91aeb83939a46fb210d21edf5c34d14c96191130c518cd44971d3c6267915bf06cb6f8b086ff8005093ae4a48d2efdf49b03392766c
+DIST fotema-v2.0.2-crates.tar.xz 61796908 BLAKE2B 729777dae5a9a684b808422c8bbbe07837b20f0bd2cbebbf10ddbdc46fe1af05fa1cf579fc7593689379ec33bb95f2151846cc6402dc3d75a0ffaa863420b142 SHA512 e96f9e6dfd90254580c9c91aeb83939a46fb210d21edf5c34d14c96191130c518cd44971d3c6267915bf06cb6f8b086ff8005093ae4a48d2efdf49b03392766c
diff --git a/media-gfx/fotema/fotema-2.0.2.ebuild b/media-gfx/fotema/fotema-2.0.2.ebuild
new file mode 100644
index 0000000000000..cb341d56fc797
--- /dev/null
+++ b/media-gfx/fotema/fotema-2.0.2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+declare -A GIT_CRATES=(
+	[rust-faces]='https://github.com/blissd/fotema-rust-faces;43c0d5acd6f3f4d90c6487708f2e511a73bf7c9e;fotema-rust-faces-%commit%'
+)
+
+RUST_MIN_VER="1.85.0"
+
+inherit cargo gnome2-utils meson xdg-utils
+
+CRATE_P=${P/-/-v}
+DESCRIPTION="Photo gallery for Linux"
+HOMEPAGE="https://github.com/blissd/fotema"
+SRC_URI="
+	https://github.com/blissd/fotema/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://github.com/gentoo-crate-dist/fotema/releases/download/v${PV}/${CRATE_P}-crates.tar.xz
+	"
+fi
+
+# see LICENSES/
+LICENSE="
+	CC-BY-2.0 CC-BY-4.0 CC-BY-NC-SA-4.0 CC-BY-SA-4.0 CC0-1.0
+	FDL-1.3+ GPL-3+ MIT
+"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD CC0-1.0
+	CDLA-Permissive-2.0 ISC MIT MPL-2.0 UoI-NCSA Unicode-3.0 WTFPL-2
+	ZLIB
+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>=dev-libs/glib-2.66:2
+	>=gui-libs/gtk-4.16:4
+"
+# indirect deps via crates
+DEPEND+="
+	dev-libs/openssl:=
+	gui-libs/libadwaita
+	media-libs/fontconfig
+	media-libs/graphene
+	media-libs/lcms:2
+	media-libs/libshumate:=
+	media-libs/opencv:=[contribdnn,features2d]
+	media-video/ffmpeg:=
+	sci-ml/onnx
+	sys-libs/libseccomp
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+"
+RDEPEND="
+	${DEPEND}
+	media-libs/glycin-loaders
+"
+BDEPEND="
+	dev-libs/glib:2
+"
+
+QA_FLAGS_IGNORED="/usr/bin/fotema"
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=$(usex debug development default)
+	)
+
+	meson_src_configure
+	ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+
+	export ORT_STRATEGY=system
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
diff --git a/profiles/package.deprecated b/profiles/package.deprecated
index d6e4a9675b7ed..031016e152cf2 100644
--- a/profiles/package.deprecated
+++ b/profiles/package.deprecated
@@ -17,6 +17,11 @@
 
 #--- END OF EXAMPLES ---
 
+# Michał Górny <mgorny@gentoo.org> (2025-06-25)
+# Discontinued upstream.  They suggest vendoring what people need
+# instead.
+dev-python/click-plugins
+
 # Michał Górny <mgorny@gentoo.org> (2024-06-15)
 # Stop-gap compatibility package.  Upstreams really need to move away
 # from the removed cgi module rather than rely on this.
diff --git a/profiles/package.mask b/profiles/package.mask
index b367686d5be80..5a927400b7a6e 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -36,6 +36,11 @@
 
 #--- END OF EXAMPLES ---
 
+# Michał Górny <mgorny@gentoo.org> (2025-06-25)
+# New problematic test dependencies.  No reverse dependencies.
+# Removal on 2025-07-25.  Bug #958987.
+dev-python/caldav
+
 # Andreas Sturmlechner <asturm@gentoo.org> (2025-06-24)
 # Qt5 package without any revdeps. Removal on 2025-07-24. Bug #938823
 dev-libs/libdbusmenu-qt