From ac36f09f35372f04207e93b29bee20061a51c028 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 28 Aug 2026 11:33:22 +0200
Subject: [PATCH] dev-python/statsmodels: Bump to 0.15.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/statsmodels/Manifest               |  1 +
 .../statsmodels/statsmodels-0.15.0.ebuild     | 84 +++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 dev-python/statsmodels/statsmodels-0.15.0.ebuild

diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index 78fad56f7639f..c8303f5bee258 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1 +1,2 @@
 DIST statsmodels-0.14.6.tar.gz 20689085 BLAKE2B fc6fe72d2f4016add10b25fb6aee7fe6a24187e4156534d7ae309c7f0b596b025b093ef45ad3201055a00361be4b8f42ba57dd0684efda8e01f6899b7ade3254 SHA512 5bb28aea779236d5f48743db624c048f78117456e1752414bd156f650098a996a81d882fd271fc5e203298dc941a656450f252a94b2d05e86b571e5ebb0b29fd
+DIST statsmodels-0.15.0.tar.gz 15736853 BLAKE2B 7adc63444bb9be9c8435f55aaf2d05d0883cf098c789dbb770bd50f08f482f3042e22a4e17a23da692fabefff22bef32f1d44c0524fef53749387e7e4518c205 SHA512 1e53c8c914c2c8e95457769f4e4125e39e1f80133fd080d43041f1ac9c1b12e06d568d4584cea1f2b2ae8a592a6466fbd95dca6090d806dfa0b3754ac1f87818
diff --git a/dev-python/statsmodels/statsmodels-0.15.0.ebuild b/dev-python/statsmodels/statsmodels-0.15.0.ebuild
new file mode 100644
index 0000000000000..c29e4dc95b835
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.15.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="
+	https://www.statsmodels.org/stable/index.html
+	https://github.com/statsmodels/statsmodels/
+	https://pypi.org/project/statsmodels/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="examples"
+
+# NB: upstream requires building with numpy-2 but supports 1.x
+# at runtime
+DEPEND="
+	>=dev-python/numpy-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/numpy-1.22.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.4[${PYTHON_USEDEP}]
+	>=dev-python/patsy-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter-client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	distutils-r1_python_prepare_all
+
+	# not actually obligatory yet
+	# TODO: package it
+	sed -i -e '/formulaic/d' pyproject.toml || die
+}
+
+python_test() {
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest -o addopts= statsmodels
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}