games-misc/ponysay: major QA refactor

- fix license (allows GPL3 or later)
- remove deps for completion - they aren't needed
- remove small-files useflag
- use upstream bash completion installer
- use edo for running setup.py

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

games-misc/ponysay/metadata.xml

@@ -6,7 +6,6 @@
 		<name>Gentoo Games Project</name>
 	</maintainer>
 	<use>
-		<flag name="fish-completion">Enable fish completion support</flag>
 		<flag name="non-free">Install non-free ponies (i.e. from the MLP franchise)</flag>
 	</use>
 	<upstream>

games-misc/ponysay/ponysay-3.0.3-r1.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} python3_13t )
+inherit edo python-single-r1
+
+DESCRIPTION="cowsay reimplemention for ponies"
+HOMEPAGE="https://github.com/erkin/ponysay"
+SRC_URI="https://github.com/erkin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~x86"
+IUSE="doc +non-free"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+BDEPEND="${PYTHON_DEPS}
+	doc? ( sys-apps/texinfo )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.3-python-syntax.patch"
+	"${FILESDIR}/${PN}-3.0.3-pr313.patch"
+)
+
+setup_py() {
+	local args=(
+		--prefix="${EPREFIX}"/usr
+		--everything
+		--without-info-compression
+		--without-man-compression
+		--without-pdf-compression
+		--without-shared-cache
+		--freedom=$(usex non-free no yes)
+		--with-bash-completion
+		--with-fish-completion
+		--with-zsh-completion
+		$(use_with doc info)
+		$(use_with doc pdf "${EPREFIX}"/usr/share/doc/${PF})
+		"${@}"
+	)
+	edo "${PYTHON}" setup.py "${args[@]}"
+}
+
+src_compile() {
+	setup_py build
+}
+
+src_install() {
+	setup_py --destdir="${D}" prebuilt
+
+	python_fix_shebang "${ED}"/usr/bin/${PN}
+
+	rm -rv "${ED}"/usr/share/licenses || die
+	dodoc CHANGELOG CONTRIBUTING CREDITS README.md
+	sed -e 's/ponysay-tool-tool/ponysay-tool/g' -i "${ED}"/usr/share/bash-completion/completions/ponysay-tool || die
+}

games-misc/ponysay/ponysay-3.0.3.ebuild

@@ -1,65 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..13} python3_13t )
-inherit bash-completion-r1 python-single-r1
-
-DESCRIPTION="cowsay reimplemention for ponies"
-HOMEPAGE="https://github.com/erkin/ponysay"
-SRC_URI="https://github.com/erkin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~x86"
-IUSE="doc +non-free bash-completion fish-completion zsh-completion"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-BDEPEND="${PYTHON_DEPS}
-	doc? ( sys-apps/texinfo )"
-
-RDEPEND="${PYTHON_DEPS}
-	fish-completion? ( app-shells/fish )
-	zsh-completion? ( app-shells/zsh )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-3.0.3-python-syntax.patch"
-	"${FILESDIR}/${PN}-3.0.3-pr313.patch"
-)
-
-setup_py() {
-	"${PYTHON}" setup.py \
-		--prefix="${EPREFIX}"/usr \
-		--everything \
-		--without-info-compression \
-		--without-man-compression \
-		--without-pdf-compression \
-		--without-shared-cache \
-		--freedom=$(usex non-free no yes) \
-		$(use_with fish-completion) \
-		$(use_with zsh-completion) \
-		$(use_with doc info) \
-		$(use_with doc pdf "${EPREFIX}"/usr/share/doc/${PF}) \
-		"${@}" || die
-}
-
-src_compile() {
-	setup_py \
-		$(use_with bash-completion) \
-		build
-}
-
-src_install() {
-	setup_py \
-		--without-bash-completion \
-		--destdir="${D}" \
-		prebuilt
-
-	python_fix_shebang "${ED}"/usr/bin/${PN}
-
-	rm -rv "${ED}"/usr/share/licenses || die
-	dodoc CHANGELOG CONTRIBUTING CREDITS README.md
-
-	use bash-completion &&
-		newbashcomp completion/bash-completion.${PN}.install ${PN}
-}