gui-libs/libdecor: Version bump to 0.2.4

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

gui-libs/libdecor/Manifest

@@ -1 +1,2 @@
 DIST libdecor-0.2.3.tar.bz2 45727 BLAKE2B 0a0adfcf90eaaba5961498665970ed4611123b8d6fc1b39d3bf1dcba32cfc681d5997fbe30786eae7964d3d12bf3f4b3b28cb5c9576a41b766bd68826c26dfff SHA512 9aa9ba80499fe34d1fb5495e5fae6bdeb9b60e39944fa75f2afcc22fb1cc0b510a5bb9a7774e3011b1902a24b34bf39b066492c356528615c1d91e398c6d15a3
+DIST libdecor-0.2.4.tar.bz2 45712 BLAKE2B 537b0eb933681491f7246feacdf9047e10367feba79535171a46592c3bc435dcac2e8e27761fc2e0a51a8ede195bd2e815efb3cdb9aade5126920a9f2e531bb3 SHA512 1e43e4848b1213f8d597aa7259f080326e14a8eccbb630226a592416890b076b8441d889b9e162a35683178c15cbd61affde29c643d74385c0729047df2045bc

gui-libs/libdecor/libdecor-0.2.4.ebuild

@@ -0,0 +1,54 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+DESCRIPTION="A client-side decorations library for Wayland clients"
+HOMEPAGE="https://gitlab.freedesktop.org/libdecor/libdecor"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/libdecor/libdecor.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.freedesktop.org/libdecor/libdecor/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="+dbus +gtk examples"
+
+RDEPEND="
+	>=dev-libs/wayland-1.18[${MULTILIB_USEDEP}]
+	x11-libs/pango[${MULTILIB_USEDEP}]
+	x11-libs/cairo[${MULTILIB_USEDEP}]
+	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+	gtk? ( x11-libs/gtk+:3[${MULTILIB_USEDEP}] )
+	examples? (
+		media-libs/libglvnd
+		x11-libs/libxkbcommon
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/wayland-protocols-1.15
+"
+
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		# Avoid auto-magic, built-in feature of meson
+		-Dauto_features=disabled
+		$(meson_feature gtk)
+		$(meson_feature dbus)
+		$(meson_native_use_bool examples demo)
+		-Dinstall_demo=true
+	)
+
+	meson_src_configure
+}