diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 3e0f882217950..eb722ff76869d 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-25.04.3.tar.xz 6519092 BLAKE2B 92d8fb42a71ab7c28ecbf18cbff6d5fdc60f8dd290c8467fb4350d2b4c963ee120b92d2ea76823835b5aa8effe4c7edfa4b0248053948a4b8402e5e9198ffdce SHA512 1ffaed038f738bc207b6b0c6f076a2684a023b8bdba3d9c1f4334806f6b9a2d6f6c295e9c63085899d390e1a51deef49bfd18a21f239137373c0e1471b83dfb3
 DIST kwave-25.08.0.tar.xz 6518688 BLAKE2B c52d86c576dfa2bb6c13851de50a39eacd041d163c407b50835d93a6176e5581a76fe191e51089a52c6a76f18064e4c1812ed70d9fe4db66437b2f795acb2c97 SHA512 81e4e7fb6eb4a77dc3f56af9410e6703d7500f87e20192712c462277a2b48dd9c67ca838622e7ac66959c8b52589addf9c4bb713099b2154f4035c0a0a12cf69
+DIST kwave-25.08.1.tar.xz 6531668 BLAKE2B 749abc62e0db799c33c533e7e77c6ed0265cd423cd4c5579da56ebf828fc6f629b72907c08bcaf1b798304ad94628d0a2e66a25f0cb9b4ca95e6e8e9b54dff03 SHA512 385db73fec43dc284f83b13241f7e2cf5f179257db472bedebf1b4484486ddd8c20970b113f9497785e54c57da96868238fcdf346cb3d8ad82f4840d1c528711
diff --git a/kde-apps/kwave/kwave-25.08.1.ebuild b/kde-apps/kwave/kwave-25.08.1.ebuild
new file mode 100644
index 0000000000000..661dd1e0449d4
--- /dev/null
+++ b/kde-apps/kwave/kwave-25.08.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=6.16.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Sound editor built on KDE Frameworks that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:6 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README.md TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}