gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-06 02:17:34 -08:00
Code Issues Projects Releases Wiki Activity

dev-python/ipykernel: Bump to 6.30.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-07-22 07:45:08 +02:00
parent f8b009cccc
commit a92b71b83e
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 80 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/ipykernel/Manifest
View File

@ -1,2 +1,3 @@
DIST ipykernel-6.29.5.tar.gz 163367 BLAKE2B ac1a48093b68a79c9b656cc3960f35ae2e28ac110b4a560b7434b853e37e505034d7822fc2d6557f03e1f82a260abba53cf53ba9dde4fc6fc468fd65fb46875a SHA512 271232ad6168ff00d6eb729bb38804f6a030b85be9bd75341b4af8ca1feb9f3c6b088eff77f4efcc503512559c93f1d78c13904089b7acb5205c4039daf0cea0
DIST ipykernel-6.30.0.tar.gz 165125 BLAKE2B 363d508e0a8bca66d8ccf26ec2806aa75e41b1a27db63366eabc64bee5e861328fcb5a0d33642d956d4f43666e1966978c5fe3fcb624ad4e43c466142d96ce72 SHA512 a5d1bd45b8e9f7fcd876a845a49c6f86cff6063ae351779f628baf9a84cc99e4012d40afea0bb4c432acc4c86d90bdeda60287aa99b48a425f5e34bd5d4fc44f
DIST ipykernel-7.0.0a1.tar.gz 169472 BLAKE2B 0377a630d16b9aa481f516e09dea4510eecb35e3dc6d69943c28048f8c6fa9bc28ff960909dd47a701981e24f412ce4e1aab60804252fe1b9e8f526e0aaefa27 SHA512 2b9b1b4e25e9d8e188008b9f11396862bdf36c4525e849f6962ce3468963b9f13ac2d20e6776fc895e51e4062a74a0da2d94fd226c4ae3c750c3a20841743d25

79
dev-python/ipykernel/ipykernel-6.30.0.ebuild Normal file
View File

@ -0,0 +1,79 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 pypi virtualx
DESCRIPTION="IPython Kernel for Jupyter"
HOMEPAGE="
https://github.com/ipython/ipykernel/
https://pypi.org/project/ipykernel/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
RDEPEND="
>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
>=dev-python/jupyter-client-8.0.0[${PYTHON_USEDEP}]
>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
>=dev-python/nest-asyncio-1.4[${PYTHON_USEDEP}]
>=dev-python/packaging-22[${PYTHON_USEDEP}]
>=dev-python/psutil-5.7[${PYTHON_USEDEP}]
>=dev-python/pyzmq-25[${PYTHON_USEDEP}]
>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
"
# RDEPEND seems specifically needed in BDEPEND, at least jupyter
# bug #816486
# pytest-8 runs a small subset of tests, we allow newer for 3.13
# since a few tests are better than skipping entirely
BDEPEND="
${RDEPEND}
test? (
dev-python/ipyparallel[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=( flaky pytest-{asyncio,timeout} )
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# TODO
tests/test_debugger.py::test_attach_debug
tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
tests/test_debugger.py::test_rich_inspect_at_breakpoint
tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
tests/test_debugger.py::test_set_breakpoints
tests/test_debugger.py::test_stop_on_breakpoint
tests/test_debugger.py::test_copy_to_globals
# hangs?
tests/test_eventloop.py::test_tk_loop
# doesn't like pyside2?
tests/test_eventloop.py::test_qt_enable_gui
)
src_prepare() {
# debugpy is actually optional
sed -i -e '/debugpy/d' pyproject.toml || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
# Use python3 in kernel.json configuration, bug #784764
sed -i -e '/python3.[0-9]\+/s//python3/' \
"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
}
src_test() {
virtx distutils-r1_src_test
}