From a8d3cd96f05c3d3b2c297e2eee82d4a4d4e0e98e Mon Sep 17 00:00:00 2001
From: NHOrus <jy6x2b32pie9@yahoo.com>
Date: Fri, 14 Feb 2025 19:41:11 +0400
Subject: [PATCH] media-libs/libggimisc: update EAPI 7 -> 8, fix impl. decls in
 configure

Autoreconf with removal of acinclude.m4

Closes: https://bugs.gentoo.org/899820
Signed-off-by: NHOrus <jy6x2b32pie9@yahoo.com>
Closes: https://github.com/gentoo/gentoo/pull/40571
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../libggimisc/libggimisc-2.2.2-r2.ebuild     | 44 +++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 media-libs/libggimisc/libggimisc-2.2.2-r2.ebuild

diff --git a/media-libs/libggimisc/libggimisc-2.2.2-r2.ebuild b/media-libs/libggimisc/libggimisc-2.2.2-r2.ebuild
new file mode 100644
index 0000000000000..61fa468d3272f
--- /dev/null
+++ b/media-libs/libggimisc/libggimisc-2.2.2-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Adds support for some special graphical target features"
+HOMEPAGE="https://ibiblio.org/ggicore/packages/libggimisc.html"
+SRC_URI="https://downloads.sourceforge.net/ggi/${P}.src.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="fbcon svga"
+
+RDEPEND=">=media-libs/libggi-2.2.2
+	svga? ( media-libs/svgalib )"
+DEPEND="${RDEPEND}"
+
+DOCS=( ChangeLog README TODO doc/ggimisc.txt doc/libggimisc{,-functions,-libraries}.txt
+	doc/retrace.txt )
+
+src_prepare() {
+	default
+
+	rm -f acinclude.m4 || die
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-x --without-x \
+		$(use_enable svga svgalib) \
+		$(use_enable fbcon fbdev)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "X extension for ${PN} has been temporarily disabled for this release."
+}