From a8d1d61c90811a9f7c99c2ee7dd7c96a02c1f41f Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 19 Jul 2026 17:21:18 +0200
Subject: [PATCH] dev-python/gpep517: Bump to 20
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/978181
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/gpep517/Manifest          |  1 +
 dev-python/gpep517/gpep517-20.ebuild | 45 ++++++++++++++++++++++++++++
 dev-python/gpep517/metadata.xml      |  2 +-
 3 files changed, 47 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/gpep517/gpep517-20.ebuild

diff --git a/dev-python/gpep517/Manifest b/dev-python/gpep517/Manifest
index 49b70aab1919a..3910d32b92066 100644
--- a/dev-python/gpep517/Manifest
+++ b/dev-python/gpep517/Manifest
@@ -1 +1,2 @@
 DIST gpep517-19.gh.tar.gz 29279 BLAKE2B 1f3002e970de1e56004a0c6486c678ee9baa51d76c263d7356b3a63086615bf81c326b0a0ee313389ae046c7c451c17a1eed1b1cada8c61f0875ee007d5caa23 SHA512 463c3812f388ea7ef83aaf6b3b90de4036b0a8200038a654621822c02d46627f7adf2ed4c7accf016293f89b8c3a2080d9ac80d2f82caaa3fdd370aa98c4335b
+DIST gpep517-20.gh.tar.gz 29306 BLAKE2B 5799cfb351741758a3e195d0496ab1e94dbb53d938ac27e1f00a81aaeb338f058a2b33ddcc4c7b073953b77e20b3d8d729c04f00b7c43928c457590818be2ee8 SHA512 3a8782eb513bb189b6d4d10516a122fa496185960a2970445058030fccde10b841e222cce04ce3bde2c3f1e1186cb8e3f50f44e40be2fd35e7e1b91e937585b0
diff --git a/dev-python/gpep517/gpep517-20.ebuild b/dev-python/gpep517/gpep517-20.ebuild
new file mode 100644
index 0000000000000..c6842881bed27
--- /dev/null
+++ b/dev-python/gpep517/gpep517-20.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{12..15} python3_{14..15}t )
+
+inherit distutils-r1
+
+DESCRIPTION="A backend script to aid installing Python packages in Gentoo"
+HOMEPAGE="
+	https://pypi.org/project/gpep517/
+	https://github.com/gentoo/gpep517/
+"
+SRC_URI="
+	https://github.com/gentoo/gpep517/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	>=dev-python/installer-0.5.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o tmp_path_retention_policy=all
+}
+
+python_install() {
+	python_domodule gpep517
+	python_newscript - gpep517 <<-EOF
+		#!${EPREFIX}/usr/bin/python
+		import sys
+		from gpep517.__main__ import main
+		sys.exit(main())
+	EOF
+}
diff --git a/dev-python/gpep517/metadata.xml b/dev-python/gpep517/metadata.xml
index 3350822dd5de8..110a34ffaebd9 100644
--- a/dev-python/gpep517/metadata.xml
+++ b/dev-python/gpep517/metadata.xml
@@ -11,7 +11,7 @@
 	</maintainer>
 	<stabilize-allarches/>
 	<upstream>
-		<remote-id type="github">projg2/gpep517</remote-id>
+		<remote-id type="github">gentoo/gpep517</remote-id>
 		<remote-id type="pypi">gpep517</remote-id>
 	</upstream>
 </pkgmetadata>