dev-python/mkdocs-git-revision-date-localized-plugin: Bump to 1.5.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/mkdocs-git-revision-date-localized-plugin/Manifest

@@ -1 +1,2 @@
 DIST mkdocs-git-revision-date-localized-plugin-1.4.7.gh.tar.gz 444162 BLAKE2B fee1e8e617362b45ee5901b7f9d10fbc24e5ac405d9de7fec13f26d71add9ca39c0091790a30229e5c33ec3f03956d50a4ab0d44ee6f65c3723b25028d446aa4 SHA512 86a1844eb5005630524d90eb381d297a21b8ccb3b0d9dbd102457554ce47f9dffce418a23e95816df040899259823fea0a339bfdb32b51af39430e747a57ad58
+DIST mkdocs-git-revision-date-localized-plugin-1.5.0.gh.tar.gz 454910 BLAKE2B 344d0744b26fb7667ac486b6e1fb8295df29bed798f6b34e193463c00fc5585bf5365330150bea5178f4f1d96fa8b3233b125362fbb9846a9354104437cc9a18 SHA512 280a1b2d101b665b9510993c0997c38678ce48c52bacf742d366e3f7a6e98952c836f3938899aa5580eb1d3dd27f6fb957ee4e6fd52eef94d8591468e5b38b99

dev-python/mkdocs-git-revision-date-localized-plugin/mkdocs-git-revision-date-localized-plugin-1.5.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{11..13} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/regex
+	dev-python/mkdocs-static-i18n
+	dev-python/mkdocs-material
+	dev-python/mkdocs-git-authors-plugin
+	dev-python/mkdocs-git-revision-date-localized-plugin
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Display the localized date of the last git modification of a markdown file"
+HOMEPAGE="
+	https://github.com/timvink/mkdocs-git-revision-date-localized-plugin/
+	https://pypi.org/project/mkdocs-git-revision-date-localized-plugin/
+"
+SRC_URI="
+	https://github.com/timvink/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/babel-2.7.0[${PYTHON_USEDEP}]
+	dev-python/gitpython[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/click[${PYTHON_USEDEP}]
+		dev-python/mkdocs-gen-files[${PYTHON_USEDEP}]
+		dev-python/mkdocs-material[${PYTHON_USEDEP}]
+		dev-python/mkdocs-monorepo-plugin[${PYTHON_USEDEP}]
+		dev-python/mkdocs-static-i18n[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+	doc? ( dev-vcs/git )
+"
+
+EPYTEST_DESELECT=(
+	# requires techdocs-core
+	"tests/test_builds.py::test_tags_are_replaced[mkdocs file: techdocs-core/mkdocs.yml]"
+)
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# mkdocs-git-revision-date-localized-plugin's tests need git repo
+	if use test || use doc; then
+		git init -q || die
+		git config --global user.email "larry@gentoo.org" || die
+		git config --global user.name "Larry the Cow" || die
+		git add . || die
+		git commit -qm 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}