sci-visualization/gwyddion: add 2.69

Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

sci-visualization/gwyddion/Manifest

@@ -1 +1,2 @@
 DIST gwyddion-2.67.tar.xz 5456028 BLAKE2B ef02681a1aa777a736340d6f4f0712da9d41e4e9644c3b6ad81f14ba4f9608390876a33aaf6eb2125cf6843f8775026fb74cc99aab7290fdfc4609855fc243ca SHA512 973ebd4a718b23b0de3340f22dbffa1a8e29da586d19838e34fa2195a29443274adba63a3f5fb68ed288ed9a6d0236acbb57fe88cff4a41ecc13845898be20fd
+DIST gwyddion-2.69.tar.xz 5476852 BLAKE2B 3043542f1d27fd56cb39ec330014d0461179f7bce89181a4df7d30a56787ffdeaafba767dd53e3c60ac2f66506f697a3591826551ac701680fb2809cb4eb788f SHA512 c11a2e7c1eb533800c97695c50227da6f58865bea002bcc9fd050d3f86e9f4aa80e426d610e9b27fde8167ced5b762f2d6f3d02106dab11348ba2af3a1812261

sci-visualization/gwyddion/gwyddion-2.69.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools xdg
+
+DESCRIPTION="Framework for Scanning Mode Microscopy data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 doc fits jansson hdf5 nls openexr openmp perl ruby sourceview unique xml X zlib"
+
+RDEPEND="
+	>=dev-libs/glib-2.32
+	dev-libs/libzip
+	media-libs/libpng:0=
+	>=sci-libs/fftw-3.1:3.0=[openmp?]
+	virtual/libiconv
+	virtual/libintl
+	x11-libs/cairo
+	>=x11-libs/gtk+-2.18:2
+	x11-libs/libXmu
+	x11-libs/pango
+	bzip2? ( app-arch/bzip2 )
+	fits? ( sci-libs/cfitsio[bzip2?] )
+	jansson? ( dev-libs/jansson )
+	hdf5? ( sci-libs/hdf5:=[hl,zlib?] )
+	openexr? ( media-libs/openexr:= )
+	perl? ( dev-lang/perl:= )
+	ruby? ( dev-ruby/narray )
+	unique? ( dev-libs/libunique:3 )
+	sourceview? ( x11-libs/gtksourceview:2.0 )
+	xml? ( dev-libs/libxml2:2= )
+	zlib? ( sys-libs/zlib )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.62-automagic.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+# There are python bindings (--enable-pygwy) but they are py2 only
+# 3D opengl rendering requires deprecated GTK-2 x11-libs/gtkglext
+src_configure() {
+	# hack for bug 741840
+	use doc && export GTK_DOC_PATH=/usr/share/gtk-doc
+
+	econf \
+		--disable-rpath \
+		--without-kde4-thumbnailer \
+		$(use_enable doc gtk-doc) \
+		$(use_enable openmp) \
+		$(use_enable nls) \
+		--disable-pygwy \
+		--without-python \
+		$(use_with bzip2) \
+		$(use_with fits cfitsio) \
+		$(use_with hdf5) \
+		$(use_with jansson) \
+		$(use_with perl) \
+		$(use_with ruby) \
+		$(use_with openexr exr) \
+		--without-gl \
+		$(use_with sourceview gtksourceview) \
+		$(use_with unique) \
+		$(use_with xml libxml2) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		--with-zip=libzip
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+}