diff --git a/dev-python/scikit-learn/Manifest b/dev-python/scikit-learn/Manifest
index bad4768bab618..53753e11c0660 100644
--- a/dev-python/scikit-learn/Manifest
+++ b/dev-python/scikit-learn/Manifest
@@ -1 +1,2 @@
 DIST scikit-learn-1.5.2.gh.tar.gz 6982418 BLAKE2B f1fdc37cdbc7625f5240b565b37b8213e1f6a21cb04886efaa2f9dad598eaa3c9bf567000cb51bcb78057172131ab3534134bb7382ed0b1df5037919d45fd65e SHA512 ed014858a9dd75765b761df03782048035228f012773d70ca3355d049d096707286b8b3d0139b88268266e8f0a6b4d430968495a87636975d094b161b9f0d712
+DIST scikit-learn-1.6.0.gh.tar.gz 7058791 BLAKE2B 57a81223d4cd2ac60cf00829f0e9b3fc404341428ec5ebbdf187f6c69213d90bf541ee6bf69a7dbe6e68225d34cf393302b098cc62e44068515b22d9e6462549 SHA512 7301503d581f908d7d70c708c44d5ec39567628c9f05a4135d69864a6bff6252fe1af6aac9c87c4c829c7e98008bab6fe964bcab6a3bb617996dc8368bb4fa60
diff --git a/dev-python/scikit-learn/scikit-learn-1.6.0.ebuild b/dev-python/scikit-learn/scikit-learn-1.6.0.ebuild
new file mode 100644
index 0000000000000..195faa635f7d6
--- /dev/null
+++ b/dev-python/scikit-learn/scikit-learn-1.6.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.19.5:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+		# doctest failing on extra shape= in repr, probably numpy version
+		cluster/_hdbscan/hdbscan.py::sklearn.cluster._hdbscan.hdbscan.HDBSCAN
+	)
+
+	rm -rf sklearn || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}