media-plugins/kodi-imagedecoder-heif: EAPI 7 -> 8, drop kodi-addon.eclass

Cleanup ebuild style and standardise

Use adaptive version dep on media-tv/kodi

Add countless missing slot ops

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

media-plugins/kodi-imagedecoder-heif/kodi-imagedecoder-heif-9999.ebuild

@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit cmake kodi-addon
+inherit cmake
 
 KODI_PLUGIN_NAME="imagedecoder.heif"
 DESCRIPTION="HEIF image decoder for Kodi"
@@ -11,18 +11,14 @@ HOMEPAGE="https://github.com/xbmc/imagedecoder.heif"
 
 case ${PV} in
 9999)
-	SRC_URI=""
 	EGIT_REPO_URI="https://github.com/xbmc/${KODI_PLUGIN_NAME}.git"
 	inherit git-r3
-	DEPEND="=media-tv/kodi-9999*"
-
 	;;
 *)
-	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 	CODENAME="Matrix"
 	SRC_URI="https://github.com/xbmc/${KODI_PLUGIN_NAME}/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz"
 	S="${WORKDIR}/${KODI_PLUGIN_NAME}-${PV}-${CODENAME}"
-	DEPEND="=media-tv/kodi-19*"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 	;;
 esac
 
@@ -30,16 +26,23 @@ LICENSE="GPL-2+"
 SLOT="0"
 IUSE=""
 
-DEPEND+="
+DEPEND="
 	>=media-libs/libde265-1.0.8
-	>=media-libs/libheif-1.6.2
-	"
-
-RDEPEND="
-	${DEPEND}
-	"
+	>=media-libs/libheif-1.6.2:=
+	=media-tv/kodi-${PV%%.*}*
+"
+RDEPEND="${DEPEND}"
 
 src_prepare() {
-	[ -d depends ] && rm -rf depends || die
+	if [[ -d depends ]]; then
+		rm -r depends || die
+	fi
 	cmake_src_prepare
 }
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR="${EPREFIX}/usr/$(get_libdir)/kodi"
+	)
+	cmake_src_configure
+}