diff --git a/dev-python/tifffile/Manifest b/dev-python/tifffile/Manifest
index 8e81dcf49f252..74a90aa4922ba 100644
--- a/dev-python/tifffile/Manifest
+++ b/dev-python/tifffile/Manifest
@@ -1 +1,2 @@
 DIST tifffile-2025.6.11.gh.tar.gz 359003 BLAKE2B 7135786b6f65c1b7dc1babf7815ce97a29882793a03e335bb1142aceb4db82315f191909fa064e48bee812fce2d68e57ace1a973513b5288bfcd86aebc62babe SHA512 b4202971e61c225578fd4f0d038599e21418801727b45738de92f0dc8bdffb3cd9b6b61777fb7898b90751c6b34de8b62e7c99240e67d565d0558e1523363519
+DIST tifffile-2025.8.28.gh.tar.gz 359713 BLAKE2B 5856af2ccc1995ec1f6c85f46f310924ff6e81122be667320ef5d503eeb83ad2ef830d1fc56a70fa37f2694a9b717a4cf1d81b4dd77cec16c89aa48f1de4bfb2 SHA512 87f2108598b3672b3c352991b2b49b1093b8bcb98c1d3f192b7c4235b3a3282d3a88e4d5471c2029c8cb61f40d9ea5ad0bd3dcfa39b79c8d07d0d5cbc48c84ed
diff --git a/dev-python/tifffile/tifffile-2025.8.28.ebuild b/dev-python/tifffile/tifffile-2025.8.28.ebuild
new file mode 100644
index 0000000000000..fa979d88561cd
--- /dev/null
+++ b/dev-python/tifffile/tifffile-2025.8.28.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Read and write TIFF files"
+HOMEPAGE="
+	https://pypi.org/project/tifffile/
+	https://github.com/cgohlke/tifffile/
+	https://www.cgohlke.com/
+"
+SRC_URI="
+	https://github.com/cgohlke/tifffile/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/numpy-1.19.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+		>=dev-python/fsspec-2021.5.0[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# not marked properly
+		# https://github.com/cgohlke/tifffile/pull/308
+		tests/test_tifffile.py::test_issue_dcp
+		# meaningless and broken on py<3.13
+		# https://github.com/cgohlke/tifffile/pull/309
+		tests/test_tifffile.py::test_gil_enabled
+	)
+
+	local -x SKIP_LARGE=1
+	local -x SKIP_HTTP=1
+
+	epytest
+}