From a56a5b66e1402841b4cfde4e2ce7fe8a9cfce1d9 Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Wed, 22 Apr 2026 07:29:44 +0300
Subject: [PATCH] app-misc/fastfetch: add 2.62.0

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.62.0.ebuild | 120 +++++++++++++++++++++
 2 files changed, 121 insertions(+)
 create mode 100644 app-misc/fastfetch/fastfetch-2.62.0.ebuild

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index aada333c413ed..e66ab55db89e3 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -2,3 +2,4 @@ DIST fastfetch-2.56.1.tar.gz 1393184 BLAKE2B abcf98fa1248b08bd79b76367b6075f06d3
 DIST fastfetch-2.58.0.tar.gz 1415337 BLAKE2B ad17dbc3d24e8fc70b87b405b4fa4f437cd2b57db9948c1cadfe3a902ea54ef41eafd1f3e7f6981b3b13e127209a4cabe7a1a680988f89cc5b1e14fbb0f60ead SHA512 f69fb50e5860a8cbb400b532658fcfd55d8dcde86e9ada00ccfaa93f902ee626c00f82e40fdc0c84bb3a13b7fd1c28220f674a04e7f00008faab8b33767eddc7
 DIST fastfetch-2.60.0.tar.gz 1428945 BLAKE2B fa1bb47489d2f5906f863da8de72f0971ecb9b2700832c2f317b6f3777b72a5fde4c1374dd46a97d229f9f1dd18a7db5273a54f1bed9b8c9207233b356b50e4f SHA512 b4984dd0b5ffbd002deea1b3c4d35d0e18857b6517fb493495fc4661448ea14861267671eefb8cd26909d6f2c0aa00989dfd18f9b34d1c1f5af8026e9457645a
 DIST fastfetch-2.61.0.tar.gz 1452448 BLAKE2B 1fabd1830fea19d764727e678340456c519bd8e5cd1098a4dd1f4a1495dedd372154c507c88056450ed4e4bfbed00ef7ed6018986355aab596ca678cba76eaaa SHA512 45bd9a0bd6b6911bf4eea419ee9f0e990b63a567c662cf1b567d7dd9f964443a55e4f061aea54a3c945d50238469d046bf45beb3c52a18bbc2921fbc25c221a8
+DIST fastfetch-2.62.0.tar.gz 1463130 BLAKE2B 8b622019b3e17c687f354a01c974914b44e72480aaae016e25ffc57f99f0951547dfd2af6d1ad103f08411b2e3885aa69603613528e0ed00e96f37d21d387214 SHA512 277d60e84dee432e77ce1ae1c6fa8de0ba9af80eab4ecf1fb192905a756858701438595b7be3606c568545182dde90d5839da08642e903cc76c347c825aa0df5
diff --git a/app-misc/fastfetch/fastfetch-2.62.0.ebuild b/app-misc/fastfetch/fastfetch-2.62.0.ebuild
new file mode 100644
index 0000000000000..a9c8a037c914d
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.62.0.ebuild
@@ -0,0 +1,120 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl pulseaudio sqlite test vulkan wayland xcb xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.12.0
+	sys-apps/hwdata
+	virtual/zlib:=
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? (
+		media-libs/libglvnd[X?]
+		X? ( x11-libs/libX11 )
+	)
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	opengl? ( X? ( x11-base/xorg-proto ) )
+	xcb? ( x11-base/xorg-proto )
+	xrandr? ( x11-base/xorg-proto )
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local glx=no
+	if use X; then
+		if use opengl; then
+			glx=yes
+		else
+			ewarn 'USE="X" adds GLX support for USE="opengl"'
+			ewarn 'This build with USE="X -opengl" will not include any extra X support.'
+		fi
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+		-DBUILD_FLASHFETCH=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=${glx}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}