dev-python/aiohttp: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-07-22 17:57:02 +02:00
parent fdc648cd41
commit a557f52891
2 changed files with 0 additions and 109 deletions
-1
View File
@@ -1,2 +1 @@
DIST aiohttp-3.8.4.tar.gz 7338512 BLAKE2B 019e39eab7cfafe4ca2781c5efe7cc63ed16b5400c548a9a5169a98b59f4014c79bf1a32def1071ac4e1890dcfa583354a227ed2a541449dc725726216b7750b SHA512 ee193320d57161ba9d96b22502cea4eddb05d9586bde5ba1ce813e0bd149f62286ab8a76f120ef2a69f8bf882ab0605ca42103c0811fe53c7a024682ee31aa1e
DIST aiohttp-3.8.5.tar.gz 7358303 BLAKE2B e1a7df12380cded655a57735527607cc95661da99fe4a5c1aec40a2586deecee97592c9ea5e9bd43621bf069fe87f00d7bef712fab2b84783e14ff229495a7c6 SHA512 613dfe836c511832c68eadbd0a76882ec362ff956937aa913fc7567b7e3e1ac2085a70a1eca42fb016f38c076a131b506b22f26879ad06b077cb4a85e9dcd8db
-108
View File
@@ -1,108 +0,0 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} pypy3 )
inherit distutils-r1 multiprocessing pypi
DESCRIPTION="HTTP client/server for asyncio"
HOMEPAGE="
https://github.com/aio-libs/aiohttp/
https://pypi.org/project/aiohttp/
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="test-rust"
RDEPEND="
app-arch/brotli[python,${PYTHON_USEDEP}]
>=dev-python/aiosignal-1.1.2[${PYTHON_USEDEP}]
>=dev-python/async-timeout-4.0.0_alpha3[${PYTHON_USEDEP}]
>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
<dev-python/charset-normalizer-4[${PYTHON_USEDEP}]
>=dev-python/charset-normalizer-2.0[${PYTHON_USEDEP}]
>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/cython[${PYTHON_USEDEP}]
test? (
app-arch/brotli[python,${PYTHON_USEDEP}]
dev-python/freezegun[${PYTHON_USEDEP}]
www-servers/gunicorn[${PYTHON_USEDEP}]
dev-python/pytest-forked[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
dev-python/re-assert[${PYTHON_USEDEP}]
test-rust? (
dev-python/trustme[${PYTHON_USEDEP}]
)
)
"
DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
distutils_enable_tests pytest
src_prepare() {
# increase the timeout a little
sed -e '/abs_tol=/s/0.001/0.01/' -i tests/test_helpers.py || die
# xfail_strict fails on py3.10
sed -i -e '/--cov/d' -e '/xfail_strict/d' setup.cfg || die
# which(1)...
sed -i -e 's:which:command -v:' Makefile || die
distutils-r1_src_prepare
}
python_configure_all() {
# workaround missing files
mkdir requirements tools || die
> requirements/cython.txt || die
> tools/gen.py || die
chmod +x tools/gen.py || die
# force rehashing first
emake requirements/.hash/cython.txt.hash
> .update-pip || die
> .install-cython || die
emake cythonize
}
python_test() {
local EPYTEST_IGNORE=(
# proxy is not packaged
tests/test_proxy_functional.py
)
local EPYTEST_DESELECT=(
# Internet
tests/test_client_session.py::test_client_session_timeout_zero
# broken by irrelevant deprecation warnings
tests/test_circular_imports.py::test_no_warnings
# TODO
tests/test_client_session.py::test_request_tracing_url_params
)
case ${EPYTHON} in
pypy3)
EPYTEST_DESELECT+=(
# C extensions are not used on PyPy3
tests/test_http_parser.py::test_c_parser_loaded
)
;;
esac
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=pytest_mock,xdist.plugin,pytest_forked
rm -rf aiohttp || die
epytest -n "$(makeopts_jobs)" --forked
}