From a43350aba997c5a3c390d477c42763ca6ba7a46e Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Mon, 20 Jan 2025 22:28:40 +0000
Subject: [PATCH] app-misc/piper: Version bump to 0.8

Closes: https://bugs.gentoo.org/940573
Signed-off-by: James Le Cuirot <chewi@gentoo.org>
---
 app-misc/piper/Manifest            |  1 +
 app-misc/piper/piper-0.7-r1.ebuild |  3 +-
 app-misc/piper/piper-0.8.ebuild    | 64 ++++++++++++++++++++++++++++++
 app-misc/piper/piper-9999.ebuild   | 13 ++----
 4 files changed, 71 insertions(+), 10 deletions(-)
 create mode 100644 app-misc/piper/piper-0.8.ebuild

diff --git a/app-misc/piper/Manifest b/app-misc/piper/Manifest
index c049b2ea7d143..9a615d205b3c4 100644
--- a/app-misc/piper/Manifest
+++ b/app-misc/piper/Manifest
@@ -1 +1,2 @@
 DIST piper-0.7.tar.gz 271658 BLAKE2B 8d3d411cc771a286ae0d7654b6d70f394e11edb182924619195b947d0d54df4db308e94aceebe0754ddd446538f1dce2ccb88dbf1cd44595b614d852e7394698 SHA512 fcbc30a4954ea6b0aa67c66052eab1e6b2d3039c927eeddcfc8b03d00f1c91e8f0ae80788ba0e4f053a612b03f594e74fd119dd11f52dd47608c99602e7e4940
+DIST piper-0.8.tar.gz 318558 BLAKE2B 170426c35899841a3317d0cd37d253fab524848fbe5ebf1c2e670c56c962bf9f7a39bccd1dea43bbf0d5c6a158e795df63e84ddb0422fec4fd92142d70fccbc8 SHA512 c0a05262262a1284911c976ab934653f8a3699066ef1d791669169c1e6c5db62dba0fcccc32d6bc68b996a2c2b8e96a6567761d01417a03d7dbb41010dd95cd8
diff --git a/app-misc/piper/piper-0.7-r1.ebuild b/app-misc/piper/piper-0.7-r1.ebuild
index ec2d208c5f69a..9fec0194967c2 100644
--- a/app-misc/piper/piper-0.7-r1.ebuild
+++ b/app-misc/piper/piper-0.7-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -41,6 +41,7 @@ RDEPEND="
 	${PYTHON_DEPS}
 	dev-libs/gobject-introspection
 	>=dev-libs/libratbag-0.14
+	<dev-libs/libratbag-0.18
 	gnome-base/librsvg[introspection]
 	x11-libs/gdk-pixbuf[introspection]
 	x11-libs/gtk+:3[introspection]
diff --git a/app-misc/piper/piper-0.8.ebuild b/app-misc/piper/piper-0.8.ebuild
new file mode 100644
index 0000000000000..82febf98c57d6
--- /dev/null
+++ b/app-misc/piper/piper-0.8.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="GTK application to configure gaming devices"
+HOMEPAGE="https://github.com/libratbag/piper"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/libratbag/piper.git"
+else
+	SRC_URI="https://github.com/libratbag/piper/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+	virtual/pkgconfig
+	test? ( dev-libs/appstream )
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection
+	>=dev-libs/libratbag-0.18
+	gnome-base/librsvg[introspection]
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/gtk+:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/evdev[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libevdev
+	virtual/libudev
+"
+
+src_configure() {
+	python_setup
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	python_fix_shebang "${ED}"/usr/bin/
+}
diff --git a/app-misc/piper/piper-9999.ebuild b/app-misc/piper/piper-9999.ebuild
index 0631b1a08ae69..82febf98c57d6 100644
--- a/app-misc/piper/piper-9999.ebuild
+++ b/app-misc/piper/piper-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{10..13} )
 
 inherit meson python-single-r1 xdg
 
@@ -30,17 +30,12 @@ BDEPEND="
 		dev-python/lxml[${PYTHON_USEDEP}]
 	')
 	virtual/pkgconfig
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/flake8[${PYTHON_USEDEP}]
-		')
-		dev-libs/appstream
-	)
+	test? ( dev-libs/appstream )
 "
 RDEPEND="
 	${PYTHON_DEPS}
 	dev-libs/gobject-introspection
-	>=dev-libs/libratbag-0.14
+	>=dev-libs/libratbag-0.18
 	gnome-base/librsvg[introspection]
 	x11-libs/gdk-pixbuf[introspection]
 	x11-libs/gtk+:3[introspection]