dev-python/entrypoints: Version bump to 0.3

Bug: https://bugs.gentoo.org/667902
Package-Manager: Portage-2.3.66, Repoman-2.3.16
Signed-off-by: Marius Brehler <marius.brehler+gentoo@googlemail.com>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-python/entrypoints/entrypoints-0.3.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Discover and load entry points from installed packages"
+HOMEPAGE="https://github.com/takluyver/entrypoints"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/configparser-3.5.0[${PYTHON_USEDEP}]' 'python2*')
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		virtual/python-pathlib[${PYTHON_USEDEP}]
+	)
+	"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-0.2.1-init.py.patch
+)
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i doc/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C doc html
+		HTML_DOCS=( doc/_build/html/. )
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	cp -r "${S}"/tests "${TEST_DIR}"/lib/ || die
+	py.test || die
+}