diff --git a/net-irc/konversation/Manifest b/net-irc/konversation/Manifest
index 6a1857ebe6c5e..5927ae9aecd45 100644
--- a/net-irc/konversation/Manifest
+++ b/net-irc/konversation/Manifest
@@ -1 +1,2 @@
 DIST konversation-25.12.2.tar.xz 4501664 BLAKE2B b569efbff037db6b57bc08a85ddd547c93125770002f846fe14e1787bfc05d2c3221733266c2063b69b0d37b7a9ded21cdec175b123309cb2d056e79128339ad SHA512 9210a3b0f1b26808711dc4a8b2fd2a80fab76fffd35c40a45fc80da3bc0148048d4863b4edf0ecdfc8924359cb8fd215869d1025b598e1c1d380e724c4c39c94
+DIST konversation-25.12.3.tar.xz 4500288 BLAKE2B d99b86d08e670db84d05c5d733f23ef3bbe16538cf1b935abee2ed9aefcf7440d467f450955fd1b90d4e848d4e6b9a010079c1c63de83d71b1a081c9164aaf19 SHA512 3560968f8cdbdad51b4c4ed1b6e7a831466470d402dfb88f69c2dea724eed8cae9acc6274836ac20baa122cc1699ef953b0d48f2ad5c8eb5c5d6464cfba8a425
diff --git a/net-irc/konversation/konversation-25.12.3.ebuild b/net-irc/konversation/konversation-25.12.3.ebuild
new file mode 100644
index 0000000000000..fa8fc71120bff
--- /dev/null
+++ b/net-irc/konversation/konversation-25.12.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+KFMIN=6.19.0
+QTMIN=6.10.1
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="User friendly IRC Client"
+HOMEPAGE="https://konversation.kde.org https://apps.kde.org/konversation/"
+
+LICENSE="GPL-2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+crypt"
+
+DEPEND="
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=dev-qt/qtmultimedia-${QTMIN}:6
+	>=dev-qt/qttools-${QTMIN}:6[qdbus]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kbookmarks-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	crypt? ( >=app-crypt/qca-2.3.7:2[qt6(+)] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:6
+	crypt? ( >=app-crypt/qca-2.3.7:2[qt6(+),ssl] )
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Qca-qt6)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# Bug 616162
+	insinto /etc/xdg
+	doins "${FILESDIR}"/konversationrc
+}