dev-python/testpath: Version Bump

Package-Manager: portage-2.2.27
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/testpath/testpath-0.3.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Test utilities for code working with files and commands"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="https://github.com/jupyter/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		virtual/python-pathlib[${PYTHON_USEDEP}]
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.2-setup.py.patch
+	)
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i doc/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+	}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	cp -r "${S}"/tests "${TEST_DIR}"/lib/ || die
+	py.test || die
+}