diff --git a/app-accessibility/at-spi2-core/Manifest b/app-accessibility/at-spi2-core/Manifest
index 72fa465f615b6..e4ce5556ad475 100644
--- a/app-accessibility/at-spi2-core/Manifest
+++ b/app-accessibility/at-spi2-core/Manifest
@@ -1 +1,2 @@
 DIST at-spi2-core-2.56.5.tar.xz 582000 BLAKE2B 4b6eef6aef038748bf1a37986ba370474e1162d382f8074fd90f1ef8609d088b078ff7c39c86518eead44f05ab690bb6789c8129b2e676b96cfc0fb2d01254bf SHA512 b495a9f7f8539c9d7a3929d8bdceb98ce0b8dac9ea735fa85aada6e1062658b7fff323c8e76a4ae34131febffa9664976f3e1e3e171154c0ff8e923c4db9d9e5
+DIST at-spi2-core-2.58.2.tar.xz 584784 BLAKE2B 52270e4359d7b67f92802723bbc99ffd1f75168d0f10598bb836da794862c2ec4b895a8b85eadd432bcc4531aee2107e09b1c8467482bf11ed3e3f27568e7dc0 SHA512 2cc9169c246624de3584db9068e49b8f7380f8dfc328fe028397a4ec6c901266c80685a0a4fdc30cdc2e8c0f1f3a34efbc304f318569f193270490851107d4ec
diff --git a/app-accessibility/at-spi2-core/at-spi2-core-2.58.2.ebuild b/app-accessibility/at-spi2-core/at-spi2-core-2.58.2.ebuild
new file mode 100644
index 0000000000000..d98682ac9a84e
--- /dev/null
+++ b/app-accessibility/at-spi2-core/at-spi2-core-2.58.2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit gnome.org meson-multilib python-r1 systemd virtualx xdg
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/at-spi2-core"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="X dbus-broker gtk-doc +introspection systemd"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	dbus-broker? ( systemd )
+	gtk-doc? ( X )
+"
+
+DEPEND="
+	>=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.67.4:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1:2=[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	systemd? ( sys-apps/systemd[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+	)
+
+	!<dev-libs/atk-2.46.0
+"
+RDEPEND="${DEPEND}
+	dbus-broker? ( sys-apps/dbus-broker )
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-python/sphinx
+		dev-util/gdbus-codegen
+		>=dev-util/gi-docgen-2021.1
+	)
+	${PYTHON_DEPS}
+	test? ( dev-python/pygobject[${PYTHON_USEDEP}] )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	python_setup
+
+	local emesonargs=(
+		-Ddefault_bus=$(usex dbus-broker dbus-broker dbus-daemon)
+		$(meson_use systemd use_systemd)
+		-Dgtk2_atk_adaptor=true
+		-Dsystemd_user_dir="$(systemd_get_userunitdir)"
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_feature introspection)
+		$(meson_feature X x11)
+		-Datk_only=false
+		-Dpython="${EPYTHON}"
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# Avoid locates using commas as decimal separators and breaking some
+	# tests
+	LC_ALL=C.UTF-8 virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	python_optimize
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/{libatspi,atk} || die
+		mv "${ED}"/usr/share/doc/libatspi "${ED}"/usr/share/gtk-doc/libatspi/html || die
+		mv "${ED}"/usr/share/doc/atk "${ED}"/usr/share/gtk-doc/atk/html || die
+	fi
+}