dev-python/tox: Version Bump

Package-Manager: portage-2.2.27
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/tox/Manifest

@@ -2,3 +2,4 @@ DIST tox-1.8.0.tar.gz 89667 SHA256 4583b8340279d8cf080082550f7a5f14ba838bed3b217
 DIST tox-1.8.1.tar.gz 90120 SHA256 44ca1e038cb57fe40ac0dff8b67b258efe05517bf9b4b4b07035f8be830aac01 SHA512 eb669c62e1943462513d66760e6275458e448552ec18a79776bceddeb686deea62280913dfe3d338809b8622dbc3fff24321f68ec6263e447ddf5099a36047bc WHIRLPOOL 240f8ab6df2bce1febb828058b2ba204ba5d48de17ccfa457e66392a9c3c49444439b5cda69e34c94e464f4bab91634104b0f935e5ac465528a2d9cfb7c14d80
 DIST tox-1.9.0.tar.gz 92574 SHA256 817ad1eaeb6b46e68b322d9ff41244be3c15315833df5762216ffe3629a21219 SHA512 71e36b7524662bc751e7260e8a589d73c1a6070e17ca5b51fb8831ad5ea54cff5404b37fb7ff8db9d62a98f496a24b3fb41d93cde9ff723b91ed931760274384 WHIRLPOOL fa4fb9f72261498c56e6489e96aab19e6d1f7418b1b487378230f62851911279afe32c9cef672c05643de1bbac5bc069437cfc53e65aeaff118e1418b91d3e96
 DIST tox-1.9.2.tar.gz 93029 SHA256 3125a15da7381f59f835a25bd259a84acb7a69858c81e386c50027bd842bb91b SHA512 a6521300825ac8b11576a224748aedefb183890bd7e3586c0c7340761e00778d20cff9cb4140ec452e62de5c2d6fc0c014b17bd45a43e45ac6a83e2394ef72b4 WHIRLPOOL 659ac6878fc845f3979d69b7d5a4d9bbd16716bb43dd5a41ac5f603d5172bef475f1da98eb806da0b16df62dd86ea03e978045bab62ccdec563261a34fbdc1a8
+DIST tox-2.3.1.tar.gz 106447 SHA256 bf7fcc140863820700d3ccd65b33820ba747b61c5fe4e2b91bb8c64cb21a47ee SHA512 0a3565dd015a0455041769ba979aefe3395d571d7aa0bd26a199cdfda420c273bff0232475a33f9e9c4679355f68ca61f2486abd6c94673d569790ab415211d3 WHIRLPOOL d37d3f939e5b0ff6d8b9ed06976a7cf6c4ce90d640bee5cd668f87755bd2be8047b0c260a48b3d8e74dfc0aefe8d6962453c573b37f4ba2f6be9820d2fd78819

dev-python/tox/tox-2.3.1.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_{3,4,5}} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="http://tox.testrun.org https://pypi.python.org/pypi/tox"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~ppc ~ppc64"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-1.11.2[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	>=dev-python/py-1.4.17[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (	>=dev-python/pytest-2.3.5[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Take out failing tests known to pass when run manually
+	# # Run from ebuild interferes in subtle & mysterious ways, inducing these erroroneous fails
+	sed \
+		-e 's:test_package_install_fails:_&:' \
+		-e 's:test_different_config_cwd:_&:' \
+		-e 's:test_develop:_&:' \
+		-e 's:test_usedevelop:_&:' \
+		-e 's:test_usedevelop_mixed:_&:' \
+		-e 's:test__test_usedevelop:_&:' \
+		-e 's:test_env_VIRTUALENV_PYTHON:_&:' \
+		-i tests/test_z_cmdline.py || die
+
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed \
+			-e "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" \
+			-i doc/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	py.test -v -v tests || die "Testsuite failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( "${S}"/doc/_build/html/. )
+	distutils-r1_python_install_all
+}