mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-07-25 21:08:35 -07:00
dev-python/ipython: Version Bump
Package-Manager: portage-2.2.27 Signed-off-by: Justin Lecher <jlec@gentoo.org>
This commit is contained in:
Justin Lecher
@@ -1,3 +1,4 @@
|
||||
DIST ipython-3.2.1.tar.gz 10884249 SHA256 c913adee7ae5b338055274c51a7d2b3cea468b5b316046fa520cd8a434b09177 SHA512 de7723e3b859d21a58a24456c76c8d8ec98c019f290f61269f46270e7647d2b49a98671138fecd75cb6f46384fde7e09618eb5c85c175e0e442c7fae7328d8fe WHIRLPOOL 9f020c167559259931dcb177d0c3a5211939632e5775c2627795ba390cf57bd62c378c15b7ee9b9ed2079180f8df8e062eb9673ed9cfc025a56f1da82c9428d1
|
||||
DIST ipython-4.0.1.tar.gz 6207566 SHA256 3bd3b78abc4f43b9ea7fa5353a2a9ba01af8ac4aec5d11e78fa5cbcec105432e SHA512 88419feca21c762a8553b4c11661e28b3305742fc89309abfd46b1213da210249b4781b754996835a2cc539569ae7cb816ed26bbaddbf15529eeb6479660265e WHIRLPOOL 58c17378fbcbac94e1585cce0cdd00996f7df20f5781a88e1e7d56b9fe2db81fe3282211dba31e8f54d2e50db869d2cce2670cfebc5c868455f481064e0089c6
|
||||
DIST ipython-4.0.3.tar.gz 6207899 SHA256 3a928f59e8ac8dd97858c28390867c87c09510f1f8bbe97e4e9c6b036eb84fc0 SHA512 1e2deb597348757e69aaeadd0632cf984056e5f7278ee5bbbd7b4233581323b07f55685b1891c23dc0977d9f30f7dc734dcf2216bc8876424cdb0f7a9294fecf WHIRLPOOL 1beb60e6daf3cea4609318e87a07307843eeb1002847f8c3c5fbe8e114ab29cb052c810884b410f1e8414437b91c5335048106756e2d88a82a7e440e3ff8fc17
|
||||
DIST ipython-4.1.0.tar.gz 4935005 SHA256 c35e658c3a5b35fa0e196c143f46a78de8a89cf2b4a19aa00be502e39f334167 SHA512 d2d6f9e64871b0c8ff414af8ce12fffc362f69a992c7581fe7e374a35cb19f30ff6c38493439498c5bb6223792c10120b2e4ccc7c901ff09bcf75837bb87b841 WHIRLPOOL c391191132a89255bab4b61bc720670bee4138cc34a121728813fe7930ab4e9c203901b8c266c0cb1d7833432a2e886bd5bfefe7be76cd3770ca4ece0134b893
|
||||
|
||||
137
dev-python/ipython/ipython-4.1.0.ebuild
Normal file
137
dev-python/ipython/ipython-4.1.0.ebuild
Normal file
@@ -0,0 +1,137 @@
|
||||
# Copyright 1999-2016 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
# $Id$
|
||||
|
||||
EAPI=5
|
||||
|
||||
PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
|
||||
PYTHON_REQ_USE='readline,sqlite,threads(+)'
|
||||
|
||||
inherit distutils-r1 eutils virtualx
|
||||
|
||||
DESCRIPTION="Advanced interactive shell for Python"
|
||||
HOMEPAGE="http://ipython.org/"
|
||||
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
||||
|
||||
LICENSE="BSD"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
IUSE="doc examples matplotlib mongodb notebook nbconvert qt4 +smp test wxwidgets"
|
||||
|
||||
REQUIRED_USE="
|
||||
test? ( doc matplotlib mongodb notebook nbconvert qt4 wxwidgets )
|
||||
doc? ( mongodb )"
|
||||
|
||||
CDEPEND="
|
||||
dev-python/decorator[${PYTHON_USEDEP}]
|
||||
dev-python/pexpect[${PYTHON_USEDEP}]
|
||||
dev-python/pickleshare[${PYTHON_USEDEP}]
|
||||
dev-python/pyparsing[${PYTHON_USEDEP}]
|
||||
dev-python/simplegeneric[${PYTHON_USEDEP}]
|
||||
dev-python/traitlets[${PYTHON_USEDEP}]
|
||||
matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
|
||||
mongodb? ( <dev-python/pymongo-3[${PYTHON_USEDEP}] )
|
||||
wxwidgets? ( $(python_gen_cond_dep 'dev-python/wxpython:*[${PYTHON_USEDEP}]' python2_7) )"
|
||||
|
||||
RDEPEND="${CDEPEND}
|
||||
notebook? (
|
||||
dev-python/notebook[${PYTHON_USEDEP}]
|
||||
dev-python/ipywidgets[${PYTHON_USEDEP}]
|
||||
)
|
||||
nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )
|
||||
qt4? ( dev-python/qtconsole )"
|
||||
DEPEND="${CDEPEND}
|
||||
>=dev-python/setuptools-18.5[${PYTHON_USEDEP}]
|
||||
test? (
|
||||
app-text/dvipng
|
||||
dev-python/jinja[${PYTHON_USEDEP}]
|
||||
$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
|
||||
>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
|
||||
dev-python/pygments[${PYTHON_USEDEP}]
|
||||
dev-python/requests[${PYTHON_USEDEP}]
|
||||
dev-python/sphinx[${PYTHON_USEDEP}]
|
||||
dev-python/testpath[${PYTHON_USEDEP}]
|
||||
>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
|
||||
x11-base/xorg-server[xvfb]
|
||||
)
|
||||
doc? (
|
||||
dev-python/cython[${PYTHON_USEDEP}]
|
||||
$(python_gen_cond_dep 'dev-python/fabric[${PYTHON_USEDEP}]' python2_7)
|
||||
>=dev-python/jsonschema-2.0[${PYTHON_USEDEP}]
|
||||
dev-python/matplotlib[${PYTHON_USEDEP}]
|
||||
>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
|
||||
dev-python/rpy[${PYTHON_USEDEP}]
|
||||
>=dev-python/sphinx-1.3[${PYTHON_USEDEP}]
|
||||
>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
|
||||
)"
|
||||
|
||||
PDEPEND="
|
||||
smp? ( dev-python/ipyparallel[${PYTHON_USEDEP}] )"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/2.1.0-substitute-files.patch
|
||||
)
|
||||
|
||||
DISTUTILS_IN_SOURCE_BUILD=1
|
||||
|
||||
python_prepare_all() {
|
||||
# Remove out of date insource files
|
||||
rm IPython/extensions/rmagic.py || die
|
||||
|
||||
# Prevent un-needed download during build
|
||||
if use doc; then
|
||||
sed -e "/^ 'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
|
||||
fi
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
use doc && emake -C docs html_noapi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
distutils_install_for_testing
|
||||
# https://github.com/ipython/ipython/issues/8639
|
||||
# Failure of some modules only in python3.4
|
||||
local fail
|
||||
run_tests() {
|
||||
pushd ${TEST_DIR} > /dev/null || die
|
||||
"${PYTHON}" -m IPython.testing.iptestcontroller --all || fail=1
|
||||
popd > /dev/null || die
|
||||
}
|
||||
VIRTUALX_COMMAND=run_tests virtualmake
|
||||
[[ ${fail} ]] && die "Tests fail with ${EPYTHON}"
|
||||
}
|
||||
|
||||
python_install() {
|
||||
distutils-r1_python_install
|
||||
|
||||
# Create ipythonX.Y symlinks.
|
||||
# TODO:
|
||||
# 1. do we want them for pypy? No. pypy has no numpy
|
||||
# 2. handle it in the eclass instead (use _python_ln_rel).
|
||||
# With pypy not an option the dosym becomes unconditional
|
||||
dosym ../lib/python-exec/${EPYTHON}/ipython \
|
||||
/usr/bin/ipython${EPYTHON#python}
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
use doc && local HTML_DOCS=( docs/build/html/. )
|
||||
use examples && local EXAMPLES=( examples/. )
|
||||
distutils-r1_python_install_all
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature "sympyprinting" dev-python/sympy
|
||||
optfeature "cythonmagic" dev-python/cython
|
||||
optfeature "%lprun magic command" dev-python/line_profiler
|
||||
optfeature "%mprun magic command" dev-python/memory_profiler
|
||||
if use nbconvert; then
|
||||
if ! has_version app-text/pandoc ; then
|
||||
einfo "Node.js will be used to convert notebooks to other formats"
|
||||
einfo "like HTML. Support for that is still experimental. If you"
|
||||
einfo "encounter any problems, please use app-text/pandoc instead."
|
||||
fi
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user