dev-ruby/css_parser: add 1.7.1

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

dev-ruby/css_parser/css_parser-1.7.1.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_DOC_DIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md "
+RUBY_FAKEGEM_TASK_TEST=""
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+GITHUB_USER="premailer"
+GITHUB_PROJECT="${PN}"
+inherit ruby-fakegem
+
+DESCRIPTION="Sass-based Stylesheet Framework"
+HOMEPAGE="https://github.com/premailer/css_parser/"
+LICENSE="MIT"
+
+SRC_URI="https://github.com/${GITHUB_USER}/${GITHUB_PROJECT}/archive/v${PV}.tar.gz -> ${GITHUB_PROJECT}-${PV}.tar.gz"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc test"
+
+ruby_add_rdepend "dev-ruby/addressable
+	virtual/ruby-ssl"
+
+ruby_add_bdepend "test? ( dev-ruby/maxitest )"
+
+all_ruby_prepare() {
+	# get rid of bundler usage
+	rm Gemfile || die
+	sed -i -e '/bundler/d' -e '/bump/d' Rakefile || die
+	sed -i -e '/bundler/d' test/test_helper.rb || die
+	# Avoid tests using the network.
+	sed -i -e '/test_loading_a_remote_file_over_ssl/,/end/ s:^:#:' test/test_css_parser_loading.rb || die
+
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib test/*.rb || die
+}