From 9f6727ef1b4673be4f9c0884bafd52c2acf55836 Mon Sep 17 00:00:00 2001
From: James Beddek <telans@posteo.de>
Date: Sun, 31 Oct 2021 15:40:28 +1300
Subject: [PATCH] app-text/libetonyek: fix build with dev-util/mdds:1/2.0

Signed-off-by: James Beddek <telans@posteo.de>
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../libetonyek/libetonyek-0.1.10-r1.ebuild    | 62 +++++++++++++++++++
 app-text/libetonyek/libetonyek-9999.ebuild    |  7 ++-
 2 files changed, 67 insertions(+), 2 deletions(-)
 create mode 100644 app-text/libetonyek/libetonyek-0.1.10-r1.ebuild

diff --git a/app-text/libetonyek/libetonyek-0.1.10-r1.ebuild b/app-text/libetonyek/libetonyek-0.1.10-r1.ebuild
new file mode 100644
index 0000000000000..e8b2ff71f53d5
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.10-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999 ]]; then
+	MDDS_VER="9999"
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+	inherit autotools git-r3
+else
+	MDDS_VER="2.0"
+	SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+	# Unkeyworded while libreoffice has no release making use of this slot
+	# KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/librevenge
+	dev-libs/libxml2
+	>=dev-util/mdds-${MDDS_VER}:1=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	media-libs/glm
+	sys-devel/libtool
+	test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		--with-mdds="${MDDS_VER}"
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}
diff --git a/app-text/libetonyek/libetonyek-9999.ebuild b/app-text/libetonyek/libetonyek-9999.ebuild
index a9b34322cd7f6..7493c2947bb9e 100644
--- a/app-text/libetonyek/libetonyek-9999.ebuild
+++ b/app-text/libetonyek/libetonyek-9999.ebuild
@@ -1,12 +1,14 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 if [[ ${PV} == *9999 ]]; then
+	MDDS_VER="9999"
 	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
 	inherit autotools git-r3
 else
+	MDDS_VER="2.0"
 	SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 fi
@@ -26,7 +28,7 @@ RDEPEND="
 	app-text/liblangtag
 	dev-libs/librevenge
 	dev-libs/libxml2
-	>=dev-util/mdds-1.5:1=
+	>=dev-util/mdds-${MDDS_VER}:1=
 	sys-libs/zlib
 "
 DEPEND="${RDEPEND}
@@ -45,6 +47,7 @@ src_prepare() {
 src_configure() {
 	local myeconfargs=(
 		--disable-werror
+		--with-mdds="${MDDS_VER}"
 		$(use_with doc docs)
 		$(use_enable static-libs static)
 		$(use_enable test tests)