dev-python/cheroot: Bump to 8.3.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/cheroot/Manifest

@@ -1 +1,2 @@
 DIST cheroot-8.3.0.tar.gz 100557 BLAKE2B f5f2fd8a11a1a8660fc37030d501e93787be46dbb79cae89cb4f6915cbf3975453c0ced6ec3bc0ebfc7dc77d555f7d86ed01bd751df6b0227cac3b1b11a82ab5 SHA512 29ff39f043b1a08b9ef653a41761ac4b97de4141cf15c5394f95736d28f7fad4c501d666fe7ff61f40c55b087d022784c7fe09c995c901040b7f2a8ed16b7d14
+DIST cheroot-8.3.1.tar.gz 104332 BLAKE2B ac79a5e84c534456067b83f11bd72cb34c0e3c850e49c69e0ff329cbe71fd4331397a38bc3b354529a8c4daea6e527733965ba8aafb33fb67e29e6a714b345cb SHA512 5aed493904d7e60118ae4b9498c10d48da553b3cbc1d713e3e870d771a7b669988d55bb0aa3223436cacdbc2249538be759a9145cf655603fbe5b88ee10e94dd

dev-python/cheroot/cheroot-8.3.1.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Cheroot is the high-performance, pure-Python HTTP server used by CherryPy."
+HOMEPAGE="https://cherrypy.org/ https://pypi.org/project/Cheroot/ https://github.com/cherrypy/cheroot"
+SRC_URI="mirror://pypi/C/${PN/c/C}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-2.6[${PYTHON_USEDEP}]
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/jaraco-context[${PYTHON_USEDEP}]
+		dev-python/jaraco-text[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-1.11.0[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e "s/use_scm_version=True/version='${PV}'/" -i setup.py || die
+	sed -e '/setuptools_scm/d' -i setup.cfg || die
+	sed -e '/--cov/d' \
+		-e '/--testmon/d' \
+		-e '/--numproc/d' \
+		-i pytest.ini || die
+
+	# broken
+	sed -e '/False.*localhost/d' \
+		-i cheroot/test/test_ssl.py || die
+
+	distutils-r1_python_prepare_all
+}