From 9dcd1de23e90239962c2750f997e2b1a44006de2 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 21 Nov 2025 03:39:54 +0100
Subject: [PATCH] dev-python/oslo-utils: Bump to 9.2.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-utils/Manifest                |  1 +
 dev-python/oslo-utils/oslo-utils-9.2.0.ebuild | 66 +++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 dev-python/oslo-utils/oslo-utils-9.2.0.ebuild

diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 99c552e0deac..4f3f0c145035 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo_utils-9.1.0.tar.gz 138207 BLAKE2B 2cea136fe949b16daf98b7f3ec92a73c86923d9bf101c215d572a7aa40502577fe5369b56e4d18fa1a58ebaa829f8241fc1e9add398f40fe8d67e834ca479e2a SHA512 8c654c363980470f2c25bc462370019c717a59152af57d366dbf73306542a0513a007bda48d36b27f3edeb6aafd19a8cc3cbd79d50d8eab7fd0a01b197d58835
+DIST oslo_utils-9.2.0.tar.gz 142524 BLAKE2B 6eab7fadbbb69c99e1c64b9442d28c6ced17f867d31bee72dda11fbdb180a19c1e648427b8d7560b600bcb834c1850cb3963548903ff19e3fcf8a11b3aa6a954 SHA512 ed6def990d94026637bc3143c881537b5a04d38e1e13f798a2e32d106a3056f110f147fd547a18d64bdd22f44a8de5f31a38e2f5d75dfb1fbe18ec33f5258533
diff --git a/dev-python/oslo-utils/oslo-utils-9.2.0.ebuild b/dev-python/oslo-utils/oslo-utils-9.2.0.ebuild
new file mode 100644
index 000000000000..4c1a92b2f27f
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-9.2.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit check-reqs distutils-r1 pypi
+
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.utils/
+	https://github.com/openstack/oslo.utils/
+	https://pypi.org/project/oslo.utils/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.10.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+	>=dev-python/pbr-6.1.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	dev-python/tzdata[${PYTHON_USEDEP}]
+"
+# qemu needed for qemu-img
+BDEPEND="
+	test? (
+		app-cdr/cdrtools
+		app-emulation/qemu
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+# note this only applies to USE=test
+CHECKREQS_DISK_BUILD=8G
+
+pkg_pretend() {
+	use test && check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	use test && check-reqs_pkg_setup
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# require eventlet
+	rm oslo_utils/tests/test_eventletutils.py || die
+}