dev-python/PyQtWebEngine: remove 5.13.2_pre1909181828

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

dev-python/PyQtWebEngine/Manifest

@@ -1,3 +1,2 @@
 DIST PyQtWebEngine-5.13.2.tar.gz 45234 BLAKE2B 4ad3aa63856cf3627c2f4ba29d93394f13297deb5e54bdd200bd419f71322d541ae72e45d70cff09cc53808f0d2430f8922d44f18bbf177c42a6b9c827854d6e SHA512 778aff78ea731230029e8dd993f4bc59a32bf74d65f06a8b3d1467efdc67e3b3caf0d9a968682c6c275c8ffdb8d85d9c756cb51727769949656620e944c736d3
 DIST PyQtWebEngine_gpl-5.12.1.tar.gz 42474 BLAKE2B 6cb333d8e429ae6b9f8c20a7486754767639693351605e85c0226ab3f1f065a549d40d69669d91f501fdf2c30346304a547e36b416d275a8bfe4ea621c0633b7 SHA512 2bcb0e4da51de9cfb5128e03c03ada77f2d4b99b0885da910584717681b96759ce4301c325cbbf43602d46746e2d37d81ed62f77dd63b33359fd5fae74d7f010
-DIST PyQtWebEngine_gpl-5.13.2.dev1909181828.tar.gz 45197 BLAKE2B 203dacf4322e8293221a59fd9a2f34a42981aefd5861e47141b3cc58770ff9cff2c0922de1f03c0eaff4b0d1c42bf26b172787cb3fbbc9367e9d8b717e927d50 SHA512 ebb1b6de8cba1619c96a4a120b51bfe885b737669f246f4e5c2cd5023320e74f0927a62a0b87586b519ab5767e0bd7b01444e7298381ffecc036682b4f1fcaae

dev-python/PyQtWebEngine/PyQtWebEngine-5.13.2_pre1909181828.ebuild

@@ -1,73 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
-inherit python-r1 qmake-utils
-
-DESCRIPTION="Python bindings for QtWebEngine"
-HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro"
-
-MY_PN=PyQtWebEngine
-MY_P=${MY_PN}_gpl-${PV/_pre/.dev}
-if [[ ${PV} == *_pre* ]]; then
-	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
-else
-	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
-fi
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="debug"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	>=dev-python/PyQt5-5.13.1[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
-	>=dev-python/PyQt5-sip-4.19.14:=[${PYTHON_USEDEP}]
-	dev-qt/qtcore:5
-	dev-qt/qtwebengine:5[widgets]
-"
-DEPEND="${RDEPEND}
-	>=dev-python/sip-4.19.14[${PYTHON_USEDEP}]
-"
-
-S=${WORKDIR}/${MY_P}
-
-src_configure() {
-	configuration() {
-		local myconf=(
-			"${PYTHON}"
-			"${S}"/configure.py
-			--qmake="$(qt5_get_bindir)"/qmake
-			$(usex debug '--debug --trace' '')
-			--verbose
-		)
-		echo "${myconf[@]}"
-		"${myconf[@]}" || die
-
-		# Fix parallel install failure
-		sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets' ${MY_PN}.pro || die
-
-		# Run eqmake to respect toolchain and build flags
-		eqmake5 -recursive ${MY_PN}.pro
-	}
-	python_foreach_impl run_in_build_dir configuration
-}
-
-src_compile() {
-	python_foreach_impl run_in_build_dir default
-}
-
-src_install() {
-	installation() {
-		emake INSTALL_ROOT="${D}" install
-		python_optimize
-	}
-	python_foreach_impl run_in_build_dir installation
-
-	einstalldocs
-}