From 9a651c0513f4f32c7d2da1c751a98ade4a34c730 Mon Sep 17 00:00:00 2001
From: Paul Zander <negril.nx+gentoo@gmail.com>
Date: Tue, 31 Mar 2026 18:30:55 +0200
Subject: [PATCH] media-libs/webrtc-audio-processing: 1.3-r4 require abseil-cpp
 with c++17

Not backporting or testing building with c++20
Use EAPI-8

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/635
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../webrtc-audio-processing-1.3-r4.ebuild     | 41 +++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 media-libs/webrtc-audio-processing/webrtc-audio-processing-1.3-r4.ebuild

diff --git a/media-libs/webrtc-audio-processing/webrtc-audio-processing-1.3-r4.ebuild b/media-libs/webrtc-audio-processing/webrtc-audio-processing-1.3-r4.ebuild
new file mode 100644
index 0000000000000..f020c269e9b3e
--- /dev/null
+++ b/media-libs/webrtc-audio-processing/webrtc-audio-processing-1.3-r4.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+DESCRIPTION="AudioProcessing library from the webrtc.org codebase"
+HOMEPAGE="https://www.freedesktop.org/software/pulseaudio/webrtc-audio-processing/"
+SRC_URI="https://freedesktop.org/software/pulseaudio/${PN}/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="1"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="cpu_flags_arm_neon"
+
+RDEPEND="<dev-cpp/abseil-cpp-20260107.0:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3-Add-generic-byte-order-and-pointer-size-detection.patch"
+	"${FILESDIR}/${PN}-1.3-big-endian-support.patch"
+	"${FILESDIR}/${PN}-1.3-x86-no-sse.patch"
+	"${FILESDIR}/${PN}-1.3-musl.patch"
+	"${FILESDIR}/${PN}-1.3-gcc15-cstdint.patch"
+)
+
+DOCS=( AUTHORS NEWS README.md )
+
+multilib_src_configure() {
+	if [[ ${ABI} == x86 ]] ; then
+		# bug #921140
+		local -x CPPFLAGS="${CPPFLAGS} -DPFFFT_SIMD_DISABLE"
+	fi
+
+	local emesonargs=(
+		-Dneon=$(usex cpu_flags_arm_neon yes no)
+	)
+	meson_src_configure
+}