From 99860707bac7ce4fa69dcd409d1049e3f08ad4c1 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 21 Jun 2025 09:11:24 +0100
Subject: [PATCH] net-libs/gtk-vnc: add 1.5.0

Closes: https://bugs.gentoo.org/915209
Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/gtk-vnc/Manifest             |  1 +
 net-libs/gtk-vnc/gtk-vnc-1.5.0.ebuild | 75 +++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 net-libs/gtk-vnc/gtk-vnc-1.5.0.ebuild

diff --git a/net-libs/gtk-vnc/Manifest b/net-libs/gtk-vnc/Manifest
index 5605c12aac8b9..649f0bdf41755 100644
--- a/net-libs/gtk-vnc/Manifest
+++ b/net-libs/gtk-vnc/Manifest
@@ -1 +1,2 @@
 DIST gtk-vnc-1.3.1.tar.xz 222204 BLAKE2B 03e51700ae0a477a2762a67ed5906ce5205025b2fb30df5fa75deb99315d2164f22ee0b97d3fc8c23648921cdba4b4a3e22045b2cb8226360ff9f468bef2162f SHA512 01c9af407f913b214814252d7b204822372293ffc5f658aa646936f9f8cdcd77589c127e4d0e893e914c61470d4616e32f7b1fa9bd3739b2a22caef6710953b9
+DIST gtk-vnc-1.5.0.tar.xz 227600 BLAKE2B b4a026bc604dda1649aeca30952f119eb20558c656252e718a79f24ee41591a0e3e3bbcaf41e72177eec1e7a91e31da397f79d3364d71114c049976f2cadf4b5 SHA512 8bf6a008eb9a425ab7d1eedfe8d3cfac76ec9dceb8b9f71afbb72ab74f54cdce36a232d2c858f60ac991ad191e206a9930d012e17372265a88f9c05303b3e6e0
diff --git a/net-libs/gtk-vnc/gtk-vnc-1.5.0.ebuild b/net-libs/gtk-vnc/gtk-vnc-1.5.0.ebuild
new file mode 100644
index 0000000000000..90578f7784c5e
--- /dev/null
+++ b/net-libs/gtk-vnc/gtk-vnc-1.5.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit flag-o-matic gnome.org vala meson python-any-r1 xdg
+
+DESCRIPTION="VNC viewer widget for GTK"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gtk-vnc"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk-doc +introspection pulseaudio sasl +vala valgrind wayland X"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=dev-libs/gmp-6.0.0:=
+	>=x11-libs/gdk-pixbuf-2.36.0:2
+	>=net-libs/gnutls-3.6.0:0=
+	>=sys-libs/zlib-1.2.11
+	>=x11-libs/gtk+-3.24.41-r1:3[introspection?,wayland?,X?]
+	>=x11-libs/cairo-1.15.0
+	elibc_musl? ( sys-libs/libucontext )
+	introspection? ( >=dev-libs/gobject-introspection-1.56.0:= )
+	pulseaudio? ( media-libs/libpulse )
+	sasl? ( >=dev-libs/cyrus-sasl-2.1.27:2 )
+	X? ( >=x11-libs/libX11-1.6.5 )
+"
+# Keymap databases code is generated with python3; configure picks up $PYTHON exported from python-any-r1_pkg_setup
+# perl for pod2man
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	valgrind? ( dev-debug/valgrind )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-lang/perl-5
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+
+	use vala && vala_setup
+}
+
+src_configure() {
+	# defang automagic dependencies, bug #927952
+	use wayland || append-cflags -DGENTOO_GTK_HIDE_WAYLAND
+	use X || append-cflags -DGENTOO_GTK_HIDE_X11
+
+	local emesonargs=(
+		$(meson_feature gtk-doc gi-docs)
+		$(meson_feature introspection)
+		$(meson_feature pulseaudio)
+		$(meson_feature sasl)
+		-Dwith-coroutine=auto # gthread on windows, libc ucontext elsewhere; neither has extra deps
+		$(meson_feature vala with-vala)
+		$(meson_use valgrind)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	meson_src_test --no-suite style
+}