From 986ec58752cde98f3457541cce31a17ba88bf620 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Mon, 28 Aug 2023 18:19:00 +0200
Subject: [PATCH] dev-python/oslo-config: Bump to 9.2.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-config/Manifest               |  1 +
 .../oslo-config/oslo-config-9.2.0.ebuild      | 59 +++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 dev-python/oslo-config/oslo-config-9.2.0.ebuild

diff --git a/dev-python/oslo-config/Manifest b/dev-python/oslo-config/Manifest
index a8944e5ca8732..da42115c7e821 100644
--- a/dev-python/oslo-config/Manifest
+++ b/dev-python/oslo-config/Manifest
@@ -1 +1,2 @@
 DIST oslo.config-9.1.1.tar.gz 160964 BLAKE2B 180b76d9425b9be72dac22379618b69265ab7016044ac81ed826134036aa988d867882116a50597df62b702bfff4460ac17e7c1d435ff9a1f0028a2ff64b7a2f SHA512 820da069642a663cad0787ee4e100720dcc9870faeaa208c8aa5be5f3c6bbbf1e5e3d2cb8c5d86765fd4114744e2fd1a00902d79200ddeba5fcec2ed61405e4e
+DIST oslo.config-9.2.0.tar.gz 161235 BLAKE2B 186b79bab199db9369dd53952a9c6f54fafe17f950d7b66ed753f173a24726a6dbd06b794c73387f5ea6e77aa54a4d5bd0ef4752a5c564dfeea4e729fdf151e7 SHA512 69d8461f4ed5d4988fe527e4022c528244e9ecf76913a7af572e8073c0218987a69e6094edc56ff14eaf1b05fc5ffe7d81bb26ff17f87e4bd29a78d7959a3935
diff --git a/dev-python/oslo-config/oslo-config-9.2.0.ebuild b/dev-python/oslo-config/oslo-config-9.2.0.ebuild
new file mode 100644
index 0000000000000..5aba0168545da
--- /dev/null
+++ b/dev-python/oslo-config/oslo-config-9.2.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Configuration API"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.config/
+	https://github.com/openstack/oslo.config/
+	https://pypi.org/project/oslo.config/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# broken by some dep upgrade
+	sed -i -e '/DeprecationWarningTestsNoOsloLog/,$d' \
+		oslo_config/tests/test_cfg.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x COLUMNS=80
+	eunittest -b
+}